Export Aperture library objects to Finder folders

Question

Inspired by the posted message by user http://discussions.apple.com/profile.jspa?userID=616539 I wrote a script that will do the following:
1. Sync Folders/SubFolders/Albums/Projects..etc hierarchy tree from Aperture to a Finder folders tree
2. At run-time the script will creates/append to a log file under (home directory)\Library\Logs\AppleScriptExportApertureLibrary.log
3. Exports all projects images versions with embedded metadata
4. Create a file system "hard links" for each photo in the respective Albums pointing to the project folder location in order to preserve space.
5. Compare modification date on the image files and modification date within Aperture and export only modified images in order to save time for a full sync/export.
6. In interactive mode you can select Export Folder location, Aperture Library location and Projects List (project list will contain project name and internal aperture project id).
7. In non-interactive (from command line) mode there are two arguments:
7a. "quiet" - exports all projects
7b. "quiet" "Project Information" - export only certain projects. the project information can be found in the log file.
8. Remove any images or folders from Finder export directory that do not exist in Aperture database any more.
Hopefully this would help anyone who is looking to export from Aperture on a regular basis. I am not sure how it will handle large amount of photos. I tested it with 3k+ photos.
Please note that you use this script at your own risk.
Here is the script code:
global theFoldersTree_G
global theLibraryPath_G
global theProcessedProjects_G
global theSelectedProjects_G
global theAllAlbums_G
global theScriptName_G
global Sqlite_G
global ApertureLibrary_G
global numExports_G
on run argv
set Sqlite_G to "/usr/bin/sqlite3"
set ApertureLibraryPath to POSIX path of (path to home folder) & "Pictures/"
set ApertureLibrary_G to ApertureLibraryPath & "Aperture Library.aplibrary/Aperture.aplib/Library.apdb"
set exportFolder to POSIX path of (path to home folder) & "Pictures/Aperture Exports/"
set theScriptName_G to "ExportApertureLibrary"
set theSelectedProjects_G to "ALL PROJECTS"
set theFoldersTree_G to {}
set theProcessedProjects_G to {}
set theAllAlbums_G to {}
set numExports_G to 0
logEvent("Started")
set theArgv1 to {}
set theArgv2 to {}
if (count of argv) ≥ 1 then
set theArgv1 to item 1 of argv
end if
if (count of argv) = 2 then
set theArgv2 to item 2 of argv
end if
logEvent("Passed ARGV 1: " & theArgv1)
logEvent("Passed ARGV 2: " & theArgv2)
if theArgv1 is not equal to "quiet" then
set theFile to (choose file with prompt "Please choose the Aperture Library file" default location POSIX file ApertureLibraryPath) as string
set ApertureLibrary_G to POSIX path of theFile & "Aperture.aplib/Library.apdb"
set exportFolder to POSIX path of (choose folder with prompt "Please choose the export folder" default location POSIX file exportFolder) as string
end if
logEvent("ApertureLibrary_G path is set to: " & ApertureLibrary_G)
logEvent("exportFolder path is set to: " & exportFolder)
try
tell application "Aperture"
logEvent("Getting list of project path information...") of me
set SqlStatement to "
select replace(A.ZLIBRARYRELATIVEPATH,'.approject',''),A.ZUUID
from ZRKFOLDER AS A
WHERE A.ZFOLDERTYPE=2
ORDER BY A.ZNAME"
set SQLProjectUUIDPath to DB_execute(SqlStatement) of me
set theProjectsOptions to SQLProjectUUIDPath as list
set end of theProjectsOptions to "ALL PROJECTS"
logEvent("Projects list: " & theProjectsOptions as string) of me
if theArgv1 is not equal to "quiet" then
set theSelectedProjects_G to choose from list SQLProjectUUIDPath with prompt "Please choose a project(s):"
end if
if theArgv2 is not equal to {} then
set theSelectedProjects_G to theArgv2
end if
logEvent("The selected projects : " & theSelectedProjects_G as string) of me
logEvent("Getting list of libraries...") of me
set theLibraryList to every library
logEvent("Found " & (count of theLibraryList) & " libraries") of me
repeat with theLibrary in theLibraryList
set theLibraryName to name of theLibrary
logEvent("Processing library: " & theLibraryName) of me
set LibraryFolders to {}
set theProcessedProjects_G to {}
tell application "Finder"
if not (exists (POSIX file (exportFolder & theLibraryName) of me)) then
logEvent("creating new folder " & theLibraryName & " at " & exportFolder) of me
make new folder at (POSIX file exportFolder of me) with properties {name:theLibraryName}
end if
end tell
set theLibraryPath_G to exportFolder & theLibraryName & "/"
logEvent("Getting list of folders...") of me
set theFolderList to every folder of library id (id of theLibrary)
logEvent("Found " & (count of theFolderList) & " folders") of me
set theRootFolderList to {}
if theFolderList is not equal to {} then
processFoldersTree(0, theFolderList) of me
repeat with theFolder in theFolderList
if (id of theFolder) is not in theFoldersTree_G as string then
logEvent("Found root folder : " & (name of theFolder) as string) of me
set end of theRootFolderList to theFolder
set end of LibraryFolders to (name of theFolder)
end if
end repeat
end if
if theRootFolderList is not equal to {} then
processFolders(theRootFolderList, theLibraryPath_G, "projects") of me
processFolders(theRootFolderList, theLibraryPath_G, "albums") of me
else
set theProjectList to every project of library id (id of theLibrary)
set end of LibraryFolders to processProjects(theProjectList, theLibraryPath_G, "projects") of me as list
processProjects(theProjectList, theLibraryPath_G, "albums") of me
end if
logEvent("Getting list of projects...") of me
set theProjectList to every project of library id (id of theLibrary)
logEvent("Found " & (count of theProjectList) & " projects") of me
logEvent("Getting list of albums...") of me
set theAlbumList to every album of library id (id of theLibrary)
logEvent("Found " & (count of theAlbumList) & " albums") of me
set theRootProjectList to {}
if theProjectList is not equal to {} then
repeat with theProject in theProjectList
if (id of theProject) is not in theProcessedProjects_G as string then
logEvent("Found root project : " & (name of theProject) as string) of me
set end of theRootProjectList to theProject
set end of LibraryFolders to (name of theProject)
end if
end repeat
end if
set theRootAlbumList to {}
if theAlbumList is not equal to {} then
processAlbumsTree(theProjectList, theFolderList) of me
set theRootAlbumList to {}
repeat with theAlbum in theAlbumList
if (id of theAlbum) is not in theAllAlbums_G as string then
logEvent("Found root album : " & (name of theAlbum) as string) of me
set end of theRootAlbumList to theAlbum
set end of LibraryFolders to (name of theAlbum)
end if
end repeat
end if
if theRootProjectList is equal to {} then
processAlbums(theRootAlbumList, theLibraryPath_G, "albums") of me
else
processProjects(theRootProjectList, theLibraryPath_G, "projects") of me
processProjects(theRootProjectList, theLibraryPath_G, "albums") of me
if theRootAlbumList is not equal to {} then
processAlbums(theRootAlbumList, theLibraryPath_G, "albums") of me
end if
end if
cleanup(LibraryFolders, theLibraryPath_G, "all") of me
end repeat
logEvent("total exports : " & numExports_G) of me
if theArgv1 is not equal to "quiet" then
display dialog "Total image exports : " & numExports_G buttons {"OK"} with title "Aperture Library Export" with icon note
end if
end tell
on error s number i partial result p from f to t
set s to "Error: " & s
logEvent(quoted form of (s))
if theArgv1 is not equal to "quiet" then
display dialog "ERROR : " & s buttons {"OK"} with title "Aperture Library Export" with icon note
end if
end try
end run
on cleanup(theObjects, thePath, theSelection)
logEvent("Cleaning export folders...") of me
logEvent("# Objects: " & (count of theObjects)) of me
logEvent("Export Folder: " & (thePath as string))
tell application "Finder"
logEvent("Getting list of folders...") of me
set theFolderList to every folder in folder (POSIX file thePath of me)
logEvent("Found " & (count of theFolderList) & " folders") of me
logEvent("Getting list of files...") of me
set theFileList to every file in folder (POSIX file thePath of me)
logEvent("Found " & (count of theFileList) & " files") of me
repeat with theFolder in theFolderList
set theFolderName to name of theFolder
if theFolderName is not in theObjects as string then
logEvent("Moving folder " & theFolder & " to trash...") of me
move theFolder to trash
end if
end repeat
if theSelection is not equal to "folder" then
repeat with theFile in theFileList
set theFileName to name of theFile
if theFileName is not in theObjects as string then
logEvent("Moving file " & theFile & " to trash...") of me
move theFile to trash
end if
end repeat
end if
end tell
logEvent("Cleaning completed...") of me
end cleanup
on logEvent(logMessage)
set theLine to quoted form of (((current date) as string) ¬
& " : " & logMessage)
do shell script "echo " & theLine & ¬
" >> ~/Library/Logs/AppleScript" & theScriptName_G & ".log"
end logEvent
on DB_lookupProjectPath(puuid)
set SqlStatement to "
select replace(rtrim(ZLIBRARYRELATIVEPATH,'.approject'),'/',':' )
from ZRKFOLDER
where
ZUUID ='" & puuid & "'"
set SqlRecords to DB_execute(SqlStatement)
return DB_record(SqlRecords, 1, 1)
end DB_lookupProjectPath
on processFolders(theFoldersList, theFolderPath, processOrder)
logEvent("processFolders... : " & theFolderPath) of me
set arrayOfFolders to {}
tell application "Aperture"
set theCount to count of theFoldersList
set theCounter to 1
repeat with theFolder in theFoldersList
set foldersOfFolder to {}
set theFolderName to name of theFolder
logEvent("Processing folder : " & theFolderName & " (" & theCounter & "/" & theCount & ")") of me
set theCounter to theCounter + 1
set end of arrayOfFolders to theFolderName
tell application "Finder"
if not (exists (POSIX file (theFolderPath & theFolderName) of me)) then
logEvent("creating new folder " & theFolderName & " at " & theFolderPath) of me
make new folder at (POSIX file theFolderPath of me) with properties {name:theFolderName}
end if
end tell
logEvent("Getting list of album...") of me
set theAlbumsListOfFolder to every album of folder id (id of theFolder)
logEvent("Found " & (count of theAlbumsListOfFolder) & " albums") of me
logEvent("Getting list of folder...") of me
set theFolderListOfFolder to every folder of folder id (id of theFolder)
logEvent("Found " & (count of theFolderListOfFolder) & " folders") of me
logEvent("Getting list of project...") of me
set theProjectsListOfFolder to every project of folder id (id of theFolder)
logEvent("Found " & (count of theProjectsListOfFolder) & " projects") of me
if theProjectsListOfFolder is not equal to {} then
set end of foldersOfFolder to processProjects(theProjectsListOfFolder, (theFolderPath & theFolderName & "/"), processOrder) of me as list
end if
if theFolderListOfFolder is equal to {} then
set end of foldersOfFolder to processAlbums(theAlbumsListOfFolder, (theFolderPath & theFolderName & "/"), processOrder) of me as list
else
if theAlbumsListOfFolder is not equal to {} then
set end of foldersOfFolder to processAlbums(theAlbumsListOfFolder, (theFolderPath & theFolderName & "/"), processOrder) of me as list
end if
set end of foldersOfFolder to processFolders(theFolderListOfFolder, (theFolderPath & theFolderName & ":"), processOrder) of me as list
end if
cleanup(foldersOfFolder, (theFolderPath & theFolderName & "/"), "all") of me
end repeat
end tell
logEvent("processFolders completed...") of me
return arrayOfFolders
end processFolders
on processFoldersTree(theParent, theFoldersList)
logEvent("processFoldersTree...") of me
tell application "Aperture"
repeat with theFolder in theFoldersList
if theParent is not 0 then
set end of theFoldersTree_G to (id of theFolder)
end if
set theFolderListOfFolder to every folder of folder id (id of theFolder)
if theFolderListOfFolder is not equal to {} then
processFoldersTree((id of theFolder), theFolderListOfFolder) of me
end if
end repeat
end tell
logEvent("processFoldersTree completed...") of me
end processFoldersTree
on processAlbumsTree(theProjectsList, theFoldersList)
logEvent("processAlbumsTree...") of me
set theAllAlbums_G to {}
tell application "Aperture"
repeat with theProject in theProjectsList
repeat with theAlbum in (every album of project id (id of theProject))
set end of theAllAlbums_G to (id of theAlbum)
end repeat
end repeat
repeat with theProject in theProjectsList
repeat with theAlbum in (every album of every subfolder of project id (id of theProject))
set end of theAllAlbums_G to (id of theAlbum)
end repeat
end repeat
repeat with theFolder in theFoldersList
repeat with theAlbum in (every album of folder id (id of theFolder))
set end of theAllAlbums_G to (id of theAlbum)
end repeat
end repeat
end tell
logEvent("processAlbumsTree completed...") of me
end processAlbumsTree
on DB_lookupImageInfo(puuid)
set SqlStatement to "
SELECT replace(A.ZLIBRARYRELATIVEPATH,'.approject',''),strftime('%m/%d/%Y %H:%M:%S',datetime(B.ZDATELASTSAVEDINDATABASE, 'unixepoch', '+31 years','localtime'))
from ZRKFOLDER AS A,ZRKVERSION AS B
where
B.ZPROJECTUUID = A.ZUUID AND
B.ZUUID ='" & puuid & "'"
set SqlRecords to DB_execute(SqlStatement)
return {theImagePath:DB_record(SqlRecords, 1, 1), theImageDate:DB_record(SqlRecords, 1, 2)}
end DB_lookupImageInfo
on processProjects(theProjectsList, theProjectPath, processOrder)
logEvent("processProjects... : " & theProjectPath) of me
logEvent("processOrder: " & processOrder) of me
set arrayOfProjects to {}
tell application "Aperture"
set theCount to count of theProjectsList
set theCounter to 1
repeat with theProject in theProjectsList
set ProjectFolders to {}
set theProjectName to name of theProject
set end of arrayOfProjects to theProjectName
set theContinue to 0
if "ALL PROJECTS" is not in theSelectedProjects_G as string then
if (id of theProject) is not in theSelectedProjects_G as string then
logEvent("Skipping project: " & theProjectName) of me
set theContinue to 1
end if
end if
if theContinue = 0 then
-- set theProjectPath to theProjectPath & DB_lookupProjectPath(id of theProject) of me
logEvent("Processing project : " & theProjectName & " (" & theCounter & "/" & theCount & ")") of me
tell application "Finder"
if not (exists (POSIX file (theProjectPath & theProjectName) of me)) then
logEvent("creating new folder " & theProjectName & " at " & theProjectPath) of me
make new folder at (POSIX file theProjectPath of me) with properties {name:theProjectName}
end if
end tell
if processOrder is equal to "projects" then
set end of theProcessedProjects_G to (id of theProject)
logEvent("Getting list of images...") of me
set theImageList to every image version of project id (id of theProject) as list
logEvent("Found " & (count of theImageList) & " images") of me
set end of ProjectFolders to processImages(theImageList, (theProjectPath & theProjectName & "/"), "project", "JPEG - Original Size") of me as list
end if
logEvent("Getting list of subfolders...") of me
set theSubfolderList to every subfolder of project id (id of theProject)
logEvent("Found " & (count of theSubfolderList) & " subfolders") of me
logEvent("Getting list of album...") of me
set theAlbumList to every album of project id (id of theProject)
logEvent("Found " & (count of theAlbumList) & " albums") of me
if theSubfolderList is equal to {} then
set end of ProjectFolders to processAlbums(theAlbumList, (theProjectPath & theProjectName & "/"), processOrder) of me as list
else
if theAlbumList is not equal to {} then
set end of ProjectFolders to processAlbums(theAlbumList, (theProjectPath & theProjectName & "/"), processOrder) of me as list
end if
set end of ProjectFolders to processSubfolders(theSubfolderList, (theProjectPath & theProjectName & "/"), processOrder) of me as list
end if
if processOrder is equal to "projects" then
cleanup(ProjectFolders, (theProjectPath & theProjectName & "/"), "all") of me
else
cleanup(ProjectFolders, (theProjectPath & theProjectName & "/"), "folder") of me
end if
end if
set theCounter to theCounter + 1
end repeat
end tell
logEvent("processProjects completed...") of me
return arrayOfProjects
end processProjects
on exportImage(imageUUID, imageName, exportFolder, imageType, isAlbum, exportSettings, imageExt)
set imageInfo to DB_lookupImageInfo(imageUUID) of me
set imageTime to theImageDate of imageInfo as Unicode text
set imageDate to date imageTime
set isExported to 0
set imageName to imageName & imageExt
set theFile to POSIX file (exportFolder & imageName)
tell application "Finder"
set isUpdate to 0
if not (exists theFile) then
logEvent("Image does not exist in folder : " & exportFolder) of me
set isUpdate to 1
else
logEvent("Get image modification date") of me
do shell script "ls -l " & quoted form of (exportFolder & imageName)
set imageFileDate to modification date of (info for theFile)
if imageDate ≥ imageFileDate then
logEvent("Image file date: " & imageFileDate as string) of me
set isUpdate to 1
end if
end if
if isUpdate = 1 then
if exists theFile then
move theFile to the trash
end if
if isAlbum is equal to "album" then
logEvent("Creating a link for image: " & imageName) of me
set theProjectFolder to theImagePath of imageInfo
do shell script "ln " & quoted form of (theLibraryPath_G & theProjectFolder & "/" & imageName) & " " & quoted form of exportFolder
else
set isExported to 1
logEvent("Exporting image: " & imageName) of me
tell application "Aperture"
if imageType is "master" then
set settings to exportSettings
export {image version id imageUUID} using settings to POSIX path of file exportFolder metadata embedded
else
set settings to exportSettings
export {image version id imageUUID} using settings to POSIX path of file exportFolder metadata embedded
end if
end tell
end if
end if
end tell
return isExported
end exportImage
on DB_execute(SqlStatement)
try
set SqlScript to Sqlite_G & space & "-separator '|'" & space & (quoted form of ApertureLibrary_G) & space & (quoted form of SqlStatement) & " 2>&1"
set SqlResult to do shell script SqlScript
set theARray to {}
set tid to AppleScript's text item delimiters
set AppleScript's text item delimiters to ASCII character 13
set SqlRecords to text items of SqlResult
set AppleScript's text item delimiters to tid
return SqlRecords
on error s number i partial result p from f to t
set s to "SQL Error: " & s
logEvent(quoted form of (s)) of me
end try
end DB_execute
on DB_record(SqlRecords, row, col)
try
set tid to AppleScript's text item delimiters
set AppleScript's text item delimiters to "|"
set SqlCols to text items of (item row of SqlRecords)
set AppleScript's text item delimiters to tid
return item col of SqlCols
on error
return {}
end try
end DB_record
on DB_lookupRecord(SqlRecords, theReturnCol, theText, theCol)
set theResult to ""
repeat with theRow in items of SqlRecords
set tid to AppleScript's text item delimiters
set AppleScript's text item delimiters to "|"
set theFields to text items of theRow
set AppleScript's text item delimiters to tid
if item theCol of theFields is equal to theText then
set theResult to item theReturnCol of theFields
exit repeat
end if
end repeat
return theResult
end DB_lookupRecord
on processImages(theImageList, exportFolder, isAlbum, exportSettings)
logEvent("processImages... : " & exportFolder) of me
if exportSettings contains "JPEG" then
set imageExt to ".jpg"
else
set imageExt to ".ANY"
end if
set arrayOfImages to {}
with timeout of 6000 seconds
set theCount to count of theImageList
set theCounter to 1
repeat with theImage in theImageList
set imageUUID to id of theImage
set imageName to name of theImage
set end of arrayOfImages to imageName & imageExt
logEvent("Processing image : " & imageName & " (" & theCounter & "/" & theCount & ")") of me
set numExports_G to numExports_G + (exportImage(imageUUID, imageName, exportFolder, "version", isAlbum, exportSettings, imageExt) of me)
set theCounter to theCounter + 1
end repeat
end timeout
return arrayOfImages
end processImages
on processAlbums(theAlbumsList, theAlbumPath, processOrder)
logEvent("processAlbums... : " & theAlbumPath) of me
set arrayOfAlbums to {}
tell application "Aperture"
set theCount to count of theAlbumsList
set theCounter to 1
repeat with theAlbum in theAlbumsList
set theAlbumName to name of theAlbum
logEvent("Processing album : " & theAlbumName & " (" & theCounter & "/" & theCount & ")") of me
set theCounter to theCounter + 1
set AlbumObjects to {}
set end of arrayOfAlbums to theAlbumName
tell application "Finder"
if not (exists (POSIX file (theAlbumPath & theAlbumName) of me)) then
logEvent("creating new folder " & theAlbumName & " at " & theAlbumPath) of me
make new folder at (POSIX file theAlbumPath of me) with properties {name:theAlbumName}
end if
end tell
logEvent("Getting list of images...") of me
set theImagesList to every image version of album id (id of theAlbum)
logEvent("Found " & (count of theImagesList) & " images") of me
if processOrder is equal to "albums" then
set end of AlbumObjects to processImages(theImagesList, (theAlbumPath & theAlbumName & "/"), "album", "JPEG - Original Size") of me as list
cleanup(AlbumObjects, (theAlbumPath & theAlbumName & "/"), "all") of me
end if
end repeat
end tell
logEvent("processAlbums completed...") of me
return arrayOfAlbums
end processAlbums
on processSubfolders(theSubfoldersList, theSubfolderPath, processOrder)
logEvent("processSubfolders... : " & theSubfolderPath) of me
set arrayOfSubfolders to {}
tell application "Aperture"
set theCount to count of theSubfoldersList
set theCounter to 1
repeat with theSubfolder in theSubfoldersList
set theSubfolderName to name of theSubfolder
logEvent("Processing subfolder : " & theSubfolderName & " (" & theCounter & "/" & theCount & ")") of me
set theCounter to theCounter + 1
set end of arrayOfSubfolders to theSubfolderName
tell application "Finder"
if not (exists (POSIX file (theSubfolderPath & theSubfolderName) of me)) then
logEvent("creating new folder " & theSubfolderName & " at " & theSubfolderPath) of me
make new folder at (POSIX file theSubfolderPath of me) with properties {name:theSubfolderName}
end if
end tell
set SubfoldersFolders to {}
logEvent("Getting list of albums ...") of me
set theAlbumsListOfSubfolder to every album of subfolder id (id of theSubfolder)
logEvent("Found " & (count of theAlbumsListOfSubfolder) & " albums") of me
logEvent("Getting list of subfolders...") of me
set theSubfoldersListOfSubfolder to every subfolder of subfolder id (id of theSubfolder)
logEvent("Found " & (count of theSubfoldersListOfSubfolder) & " subfolders") of me
if theSubfoldersListOfSubfolder is equal to {} then
set end of SubfoldersFolders to processAlbums(theAlbumsListOfSubfolder, (theSubfolderPath & theSubfolderName & "/"), processOrder) of me as list
else
if theAlbumsListOfSubfolder is not equal to {} then
set end of SubfoldersFolders to processAlbums(theAlbumsListOfSubfolder, (theSubfolderPath & theSubfolderName & "/"), processOrder) of me as list
end if
set end of SubfoldersFolders to processSubfolders(theSubfoldersListOfSubfolder, (theSubfolderPath & theSubfolderName & "/"), processOrder) of me as list
end if
cleanup(SubfoldersFolders, (theSubfolderPath & theSubfolderName & "/"), "all") of me
end repeat
end tell
logEvent("processSubfolders completed...") of me
return arrayOfSubfolders
end processSubfolders

Answer 1

If you do externalize your Masters to folders anywhere (same drive, internal/external drive, multiple drives, whatever), never be tempted to use Finder to mess with them.
As Frank said, use Relocate Masters.  Otherwise you'll confuse Aperture when it wakes up expecting Masters to be in certain places when they have moved elsewhere.
It's possible to fix up the mess, but it's no fun!