FindText doesn't work in Acrobat X

Question

I have installed the Adobe Acrobat software development kit and until the Acrobat 9 the FindText function works correctly.
With Acrobat X (last update 10.1.3) the FindText doesn't work.
When you solve this malfunction? Is it possible to have a valid alternative?
Thanks in advance.
PS. This issue is similar to the following:
http://forums.adobe.com/thread/826756
http://forums.adobe.com/message/3762837

Answer 1

I have the same problem, looks like a bug to me...
I did found a workaround, although it's much slower. (Especially if you don't have the start page number)
The code exists of a class and a module. It will need to be adjusted for your own usage...
Hope it can help you...
Sorry for type faults (Native dutch speaking)
Module:
Option Compare Database
Option Explicit
Public clsFind As clsAcroFind
'Call on form load
Public Sub SetClass()
    Set clsFind = New clsAcroFind
    clsFind.AcroApp_Init
    clsFind.AcroPDDoc_Init
End Sub
'Call on form unload/close
Public Sub UnloadClass()
    If Not clsFind Is Nothing Then
        clsFind.AcroPDTextSelect_Unload
        clsFind.AcroAVDoc_Close
        clsFind.AcroAVDoc_Unload
        clsFind.AcroPDDoc_Close
        clsFind.AcroPDDoc_Unload
        clsFind.AcroApp_Close
        clsFind.JSO_Unload
        Set clsFind = Nothing
    End If
End Sub
'Find and highlight text in PDF
Public Function FindTextInPDF(ByRef frm As Form)   
    If clsFind Is Nothing Then
        Call SetClass
    ElseIf clsFind.AcroApp Is Nothing Then
        clsFind.AcroApp_Init
        clsFind.AcroPDDoc_Init
    End If
    clsFind.SearchText = 'Your search text
    clsFind.PageNr =  'Your start page number
    If clsFind.Initialised = True Then
        If clsFind.FileName <> FileName Then
            clsFind.AcroAVDoc_Close
            clsFind.AcroPDDoc_Close
            clsFind.FileName = 'Your PDF filename
            clsFind.Path =  'Your PDF full path (incl. filename)
            If clsFind.CheckPath = True Then
                clsFind.AcroPDDoc_Open
                clsFind.AcroAVDoc_Open
            Else
                MsgBox "File not found:" & vbCrLf & clsFind.Path, vbExclamation
                Exit Function
            End If
        End If
    Else
        clsFind.FileName = 'Your PDF filename
        clsFind.Path =  'Your PDF full path (incl. filename)
        If clsFind.CheckPath = True Then
            clsFind.AcroPDDoc_Init
            clsFind.AcroPDDoc_Open
            clsFind.AcroAVDoc_Open
        Else
            MsgBox "File not found:" & vbCrLf & clsFind.Path, vbExclamation
            Exit Function
        End If
    End If
    clsFind.JSO_Init
    clsFind.FollowInPDF
End Function
Class: (clsAcroFind)
Option Compare Database
Option Explicit
Private cPath As String
Private cFileName As String
Private cSearchText As String
Private cPageNr As Integer
Private cInitialised As Boolean
Private cAcroApp As Acrobat.cAcroApp
Private cAcroPDDoc As AcroPDDoc
Private cAcroAVDoc As AcroAVdoc
Private cAcroRect As AcroRect
Private cAcroPDTextSelect As AcroPDTextSelect
Private cJSO As Object
'********************************************** Properties **********************************************
Public Property Get Path() As String
    Path = cPath
End Property
Public Property Let Path(val As String)
    cPath = val
End Property
Public Property Get FileName() As String
    FileName = cFileName
End Property
Public Property Let FileName(val As String)
    cFileName = val
End Property
Public Property Get SearchText() As String
    SearchText = cSearchText
End Property
Public Property Let SearchText(val As String)
    cSearchText = val
End Property
Public Property Get PageNr() As String
    PageNr = cPageNr
End Property
Public Property Let PageNr(val As String)
    cPageNr = val
End Property
Public Property Get Initialised() As Boolean
    Initialised = cInitialised
End Property
'********************************************** Properties **********************************************
'********************************************** Object Set **********************************************
Public Property Get AcroApp() As Acrobat.cAcroApp
    Set AcroApp = cAcroApp
End Property
Public Sub AcroApp_Init()
    Set cAcroApp = CreateObject("AcroExch.App")
End Sub
Public Sub AcroApp_Close()
    If Not cAcroApp Is Nothing Then
        cAcroApp.Exit
        Set cAcroApp = Nothing
    End If
End Sub
Public Sub AcroPDDoc_Init()
    Set cAcroPDDoc = CreateObject("AcroExch.PDDoc")
End Sub
Public Sub AcroPDDoc_Open()
    cAcroPDDoc.Open cPath
    cInitialised = True
End Sub
Public Sub AcroPDDoc_Close()
    If Not cAcroPDDoc Is Nothing Then
        cAcroPDDoc.Close
    End If
    cInitialised = False
End Sub
Public Sub AcroPDDoc_Unload()
    Set cAcroPDDoc = Nothing
End Sub
Public Sub AcroAVDoc_Open()
    Set cAcroAVDoc = cAcroPDDoc.OpenAVDoc(cFileName)
    While cAcroAVDoc Is Nothing
        Set cAcroAVDoc = cAcroApp.GetActiveDoc
    Wend
    cAcroAVDoc.BringToFront
    cAcroAVDoc.Maximize 1
End Sub
Public Sub AcroAVDoc_Close()
    If Not cAcroAVDoc Is Nothing Then
        cAcroAVDoc.Close True
    End If
End Sub
Public Sub AcroAVDoc_Unload()
    Set cAcroAVDoc = Nothing
End Sub
Public Sub AcroPDTextSelect_Unload()
    Set cAcroPDTextSelect = Nothing
End Sub
Public Sub JSO_Init()
    Set cJSO = cAcroPDDoc.GetJSObject
End Sub
Public Sub JSO_Unload()
    Set cJSO = Nothing
End Sub
'********************************************** Object Set **********************************************
'********************************************** Functions ***********************************************
Public Function CheckPath() As Boolean
    If Dir(cPath, vbNormal) = "" Then
        CheckPath = False
    Else
        CheckPath = True
    End If
End Function
Public Sub FollowInPDF()
    Dim oAcroRect As AcroRect
    Dim arr() As String
    Dim arrQ As Variant
    Dim bFound, Gevonden As Boolean
    Dim j, k, page, nwords As Integer
    On Error GoTo ErrorHandler
    arr = Split(cSearchText, " ")
    If cJSO Is Nothing Then
        Call AcroApp_Init
        Call AcroPDDoc_Init
        Call AcroPDDoc_Open
        Call AcroAVDoc_Open
        Call JSO_Init
    End If
    '**************************** In Case a page nr was given ****************************
    If cPageNr <> 0 Then
        page = cPageNr
        nwords = cJSO.getPageNumWords(page)
        For j = 1 To nwords - 1
            Gevonden = True
            For k = 0 To UBound(arr)
                If cJSO.getPageNthWord(page, j + (k - 1)) <> Left(arr(k), Len(cJSO.getPageNthWord(page, j + (k - 1)))) Then
                    Gevonden = False
                End If
            Next
            If Gevonden = True Then
                arrQ = cJSO.getPageNthWordQuads(page, j)
                Set oAcroRect = CreateObject("AcroExch.Rect")
                oAcroRect.Left = 'Set left rectagle boundery
                oAcroRect.Right =  'Set right rectagle boundery
                oAcroRect.Top = arrQ(0)(1)
                oAcroRect.Bottom = arrQ(0)(5)
                Set cAcroPDTextSelect = cAcroPDDoc.CreateTextSelect(page, oAcroRect)
                If Not cAcroPDTextSelect Is Nothing Then
                    cAcroAVDoc.SetTextSelection cAcroPDTextSelect
                    cAcroAVDoc.ShowTextSelect
                Else
                    MsgBox "Not Found!", vbExclamation
                End If
                GoTo Finalize
            End If
        Next
    End If
    '**************************** In Case the pagenr was given ****************************
    '***** In Case the pagenr was absent or the searchtext wasn't found on given page *****
    For page = 1 To cAcroPDDoc.GetNumPages - 1
        nwords = cJSO.getPageNumWords(page)
        For j = 1 To nwords - 1
            Gevonden = True
            For k = 0 To UBound(arr)
                If cJSO.getPageNthWord(page, j + (k - 1)) <> Left(arr(k), Len(cJSO.getPageNthWord(page, j + (k - 1)))) Then
                    Gevonden = False
                End If
            Next
            If Gevonden = True Then
                arrQ = cJSO.getPageNthWordQuads(page, j)
                Set oAcroRect = CreateObject("AcroExch.Rect")
                oAcroRect.Left = 'Set left rectagle boundery
                oAcroRect.Right =  'Set right rectagle boundery
                oAcroRect.Top = arrQ(0)(1)
                oAcroRect.Bottom = arrQ(0)(5)
                Set cAcroPDTextSelect = cAcroPDDoc.CreateTextSelect(page, oAcroRect)
                If Not cAcroPDTextSelect Is Nothing Then
                    cAcroAVDoc.SetTextSelection cAcroPDTextSelect
                    cAcroAVDoc.ShowTextSelect
                Else
                    MsgBox "Not Found!", vbExclamation
                End If
                GoTo Finalize
            End If
        Next
    Next
    '***** In Case the pagenr was absent or the searchtext wasn't found on given page *****
    MsgBox "Item not found!", vbExclamation
    GoTo Finalize
ErrorHandler:
    MsgBox Err.Description
Finalize:
    Set oAcroRect = Nothing
End Sub
'********************************************** Functions ***********************************************