Fm use for writing idoc programing

Question

hi expects,
  can any body help me by providing the fm of idoc .by using it i can write the code for inbound and outbound.
       thank you

Answer 1

Hi Rohit,
Please check this sample code to create an inbound IDoc using FM IDOC_INBOUND_WRITE_TO_DB.
  PERFORM FILL_EDIDC.
  PERFORM FILL_EDIDD.
  CALL FUNCTION 'IDOC_INBOUND_WRITE_TO_DB'
    EXPORTING
      PI_STATUS_MESSAGE       = I_EDIDS
    IMPORTING
      PE_IDOC_NUMBER          = DOCNUM
      PE_STATE_OF_PROCESSING  = STPROC
      PE_INBOUND_PROCESS_DATA = I_TEDE2
    TABLES
      T_DATA_RECORDS          = I_EDIDD
    CHANGING
      PC_CONTROL_RECORD       = I_EDIDC
    EXCEPTIONS
      IDOC_NOT_SAVED          = 1
      OTHERS                  = 2.
Also check this sample code to create outbound IDoc using FM MASTER_IDOC_DISTRIBUTE.
REPORT Z_IDOC_SAMPLE
MESSAGE-ID ZLKPL_MSGCLASS
LINE-COUNT 65(5)
LINE-SIZE 132.
*& Report Z_IDOC_SAMPLE *
* REPORT:Z_IDOC_SAMPLE
* This report creates an IDOC and fills it with application data
* The control, data, status records are filled and distributed
* over the ALE Interface
* Parameters
*---Parameter for Object Key
PARAMETERS: P_ENUM LIKE ZAK_EMPLIST-ENUMBER.
*---Parameter for Message type
PARAMETERS: P_MESTYP LIKE EDMSG-MSGTYP OBLIGATORY.
*---Parameter for Destination System
PARAMETERS: P_LOGSYS LIKE TBDLST-LOGSYS.
* Constants
*---Segment Names
DATA: C_EMP_HEADER_SEGMENT LIKE EDIDD-SEGNAM VALUE 'Z1EMPHD',
C_EMP_DETAILS_SEGMENT LIKE EDIDD-SEGNAM VALUE 'Z1EMPDT'.
*---IDoc Type
DATA: C_REPORT_IDOC_TYPE LIKE EDIDC-IDOCTP VALUE 'ZREP01'.
* Data Declarations
*---Idoc Control Record
DATA: CONTROL_RECORD_OUT LIKE EDIDC.
*---Employee Header Data
DATA: FS_EMPHDR_DATA LIKE Z1EMPHD.
*---Employee Details Data
DATA: FS_EMPDET_DATA LIKE Z1EMPDT.
* Database Tables
TABLES: ZAK_EMPLIST.
* Internal Tables
*---Internal table for application data
DATA: IT_EMP LIKE ZAK_EMPLIST OCCURS 0 WITH HEADER LINE.
*---Internal table for Data Records
DATA: IT_EDIDD LIKE EDIDD OCCURS 0 WITH HEADER LINE.
*---Internal table for Communication Idocs generated
DATA: IT_COMM_IDOCS LIKE EDIDC OCCURS 0 WITH HEADER LINE.
* Select Applcation Data
SELECT * FROM ZAK_EMPLIST
WHERE ENUMBER = P_ENUM.
IF SY-SUBRC NE 0 .
MESSAGE E001(ZLKPL_MSGCLASS).
EXIT.
ENDIF.
* Build Control records
CONTROL_RECORD_OUT-MESTYP = P_MESTYP.
CONTROL_RECORD_OUT-IDOCTP = C_REPORT_IDOC_TYPE.
CONTROL_RECORD_OUT-RCVPRT = 'LS'.
CONTROL_RECORD_OUT-RCVPRN = P_LOGSYS.
* Build Data records
*--- Employee Header data
FS_EMPHDR_DATA-ENUMBER = ZAK_EMPLIST-ENUMBER.
*--- Fill the administrative information for the record
IT_EDIDD-SEGNAM = C_EMP_HEADER_SEGMENT.
IT_EDIDD-SDATA = FS_EMPHDR_DATA.
*--- Append the data
APPEND IT_EDIDD.
*--- Employee Details
FS_EMPDET_DATA-ENAME = ZAK_EMPLIST-ENAME.
FS_EMPDET_DATA-EPHONE = ZAK_EMPLIST-EPHONE.
FS_EMPDET_DATA-EDEPT = ZAK_EMPLIST-EDEPT.
*--- Fill the administrative information for the record
IT_EDIDD-SEGNAM = C_EMP_DETAILS_SEGMENT.
IT_EDIDD-SDATA = FS_EMPDET_DATA.
*--- Append the data
APPEND IT_EDIDD.
ENDSELECT.
* Pass Control to the ALE Interface -- IDoc Exporting
CALL FUNCTION 'MASTER_IDOC_DISTRIBUTE'
EXPORTING
MASTER_IDOC_CONTROL = CONTROL_RECORD_OUT
TABLES
COMMUNICATION_IDOC_CONTROL = IT_COMM_IDOCS
MASTER_IDOC_DATA = IT_EDIDD
EXCEPTIONS
ERROR_IN_IDOC_CONTROL = 1
ERROR_WRITING_IDOC_STATUS = 2
ERROR_IN_IDOC_DATA = 3
SENDING_LOGICAL_SYSTEM_UNKNOWN = 4
OTHERS = 5
IF SY-SUBRC NE 0.
MESSAGE E001(ZLKPL_MSGCLASS).
ELSE.
LOOP AT IT_COMM_IDOCS.
WRITE: / 'IDOC GENERATED', IT_COMM_IDOCS-DOCNUM.
ENDLOOP.
COMMIT WORK.
ENDIF.
Regards,
Ferry Lianto