Formatting the next paragraph

Question

I am thankful that Adobe has made InDesign so thoroughly scriptable. Nothing is better than the speed and accuracy you get with a good scripting solution! And I’m grateful for the great discussion forum; usually I can find an answer to any issue here. Unfortunately I haven’t found an answer to this problem (I’m probably not looking in the right places.) Hopefully someone out there can help me.
I am working on an InDesign CS3 document and using AppleScript. I need to apply a paragraph style to 366 paragraphs. The document is structured this way:
Date paragraph (which has an already applied paragraph style called “Date”)
Title paragraph (to which I would like to apply a paragraph style called “Title”)
Body paragraphs
How can I use AppleScript to apply the paragraph style “Title” to those Title paragraphs? The only commonality they have is that, in every instance, they immediately follow a Date paragraph.
Thanks in advance!

Answer 1

Hi,
sorry didn't read your post as carefully as I should have ...
set toSearch to "Date"
set toSet to "Title"
tell application "Adobe InDesign CS3"
    tell active document
        set myStories to every story
        repeat with i from 1 to count of myStories
            set myStory to item i of myStories
            tell myStory
                --get indexes of pStyles whose applied Paragraph Style is toSearch
                set dateParaList to (index of every paragraph whose (name of applied paragraph style is toSearch))
                repeat with p from (count of dateParaList) to 1 by -1
                    set myIndex to (item p of dateParaList)
                    try
                        set applied paragraph style of (first paragraph whose (index is greater than myIndex)) to toSet
                    end try
                end repeat
            end tell
        end repeat
    end tell
end tell
Hope it'll work
Another approach could be to use find-change-scripting.