Function Call

Question

Hi,
I want to make a call to a function that returns a cursor. Is this possible? Can you return a cursor from a function? How would you do it?

Answer 1

This is 9i code - if on 8i or earlier you'll need to replace the sys_refcursor reference with your specific ref cursor type declaration.
sql>create or replace package pkg_rc
  2  is
  3    procedure p_rc;
  4 
  5    function f_rc
  6      return sys_refcursor;
  7  end;
  8  /
Package created.
sql>create or replace package body pkg_rc
  2  is
  3 
  4    procedure p_rc
  5    is
  6      v_rc    sys_refcursor;
  7      v_id    all_objects.object_id%type;
  8      v_name  all_objects.object_name%type;
  9    begin
10      v_rc := f_rc();
11      loop
12        fetch v_rc into v_id, v_name;
13        exit when v_rc%notfound;
14        dbms_output.put_line( v_id || ', ' || v_name );     
15      end loop; 
16      close v_rc;
17    end;
18 
19    function f_rc
20      return sys_refcursor
21    is
22      v_rc  sys_refcursor;
23    begin
24      open v_rc for
25        select object_id, object_name
26          from all_objects
27         where rownum <= 5;
28   
29      return (v_rc);
30    end;
31   
32  end;
33  /
Package body created.
sql>exec pkg_rc.p_rc
17230, /1005bd30_LnkdConstant
7144, /10076b23_OraCustomDatumClosur
22726, /10297c91_SAXAttrList
13554, /103a2e73_DefaultEditorKitEndP
22291, /1048734f_DefaultFolder
PL/SQL procedure successfully completed.