Function for calculating working days

Question

Dear Oracle
Is there any function to calculate no of working days if I pass From date & To date?.
Thanks
Christy.

Answer 1

This would work for normal weekdays, but what about bank holidays?
They change from country to country, so you need to create a package yourself.
We got one that looks like the following:
create or replace
package body zentr_date_functions as
  function eastern (p_year in number) return date is
    -- Get easter sunday (working from 1900 to 2099)
    -- CKL 02.09.1998 nach c't 18/98
    l_a pls_integer;
    l_b pls_integer;
    l_c pls_integer;
    l_d pls_integer;
    l_e pls_integer;
    l_p pls_integer;
    function make_date(p_d in pls_integer, p_m in pls_integer, p_y in pls_integer) return date is
    begin
      return to_date(to_char(p_d, '00')||to_char(p_m, '00')||to_char(p_y, '0000'), 'DDMMYYYY');
    end;
  begin
    if p_year not between 1900 and 2099 then
      return null;
    end if;
    l_a := mod(p_year, 19);
    l_b := mod(p_year, 4);
    l_c := mod(p_year, 7);
    l_d := mod(19 * l_a + 24, 30);
    l_e := mod(2 * l_b + 4 * l_c + 6 * l_d + 5, 7);
    l_p := 22 + l_d + l_e;
    if l_p > 31 then
      if l_p = 56 and l_d = 28 and l_a > 10 then
        return make_date(18, 4, p_year);
      elsif l_p = 57 then
        return make_date(19, 4, p_year);
      else
        return make_date(l_p - 31, 4, p_year);
      end if;
    else
      return make_date(l_p, 3, p_year);
    end if;
  end eastern;
  function is_workday (p_date in date) return number as
    -- is this a working day?
    l_eastern date;
  begin
    if to_char(p_date, 'DY', 'NLS_DATE_LANGUAGE = AMERICAN') in ('SAT', 'SUN') then
      return 0;
    end if;
    if to_char(p_date, 'DDMM') in ('0101', '0105', '0310', '2412', '2512', '2612', '3112') then
      -- fixed date bank holidays in lower saxony, Germany
      return 0;
    end if;
    if to_number(to_char(p_date, 'MM')) not between 3 and 6 then
      return 1;
    end if;
    if to_number(to_char(p_date, 'YYYY')) not between 1900 and 2099 then
      -- calculation not possible
      return null;
    end if;
    l_eastern := eastern (to_number(to_char(p_date, 'YYYY')));
    if trunc(p_date) in (l_eastern - 2, l_eastern + 1, l_eastern + 39, l_eastern + 50) then
      -- good friday, easter monday, ascension day, pentecost monday
      return 0;
    end if;
    return 1;
  end is_workday;
  function workdays_between (p_date1 in date, p_date2 in date) return number as
    -- count number of working days between  p_date1 and p_date2 (incl. both)
    l_count pls_integer := 0;
  begin
    for i in 0 .. p_date2 - p_date1 loop
      l_count := l_count + is_workday(p_date1 + i);
    end loop;
    return l_count;
  end workdays_between;
end;
/