Is there a function to derive "business days" only

Question

Is there either an Oracle SQL built-in function or user-defined function for calculating the difference
between two dates or between SYSDATE and a date in the database, which uses business days
only (at least excluding weekends)?
I'd appreciate any help on this!
Thanks!
Kathy Kuehnle
[ [email protected] ]

Answer 1

We solved this with the following package:
create or replace
package body zentr_date_functions as
  function eastern (p_year in number) return date is
    -- Calculate easter sunday (valid from 1900 to 2099)
    -- based on a Gauss algorithm
    l_a pls_integer;
    l_b pls_integer;
    l_c pls_integer;
    l_d pls_integer;
    l_e pls_integer;
    l_p pls_integer;
    function make_date(p_d in pls_integer, p_m in pls_integer, p_y in pls_integer) return date is
    begin
      return to_date(to_char(p_d, '00')||to_char(p_m, '00')||to_char(p_y, '0000'), 'DDMMYYYY');
    end;
  begin
    if p_year not between 1900 and 2099 then
      return null;
    end if;
    l_a := mod(p_year, 19);
    l_b := mod(p_year, 4);
    l_c := mod(p_year, 7);
    l_d := mod(19 * l_a + 24, 30);
    l_e := mod(2 * l_b + 4 * l_c + 6 * l_d + 5, 7);
    l_p := 22 + l_d + l_e;
    if l_p > 31 then
      if l_p = 56 and l_d = 28 and l_a > 10 then
        return make_date(18, 4, p_year);
      elsif l_p = 57 then
        return make_date(19, 4, p_year);
      else
        return make_date(l_p - 31, 4, p_year);
      end if;
    else
      return make_date(l_p, 3, p_year);
    end if;
  end eastern;
  function is_workday (p_date in date) return number as
    -- Is p_date a working day?
    l_eastern date;
  begin
    if to_char(p_date, 'DY', 'NLS_DATE_LANGUAGE = AMERICAN') in ('SAT', 'SUN') then
      return 0;
    end if;
    if to_char(p_date, 'DDMM') in ('0101', '0105', '0310', '2412', '2512', '2612', '3112') then
      return 0; -- fixed bank holidays in lower saxony, Germany
    end if;
    if to_number(to_char(p_date, 'MM')) not between 3 and 6 then
      return 1;
    end if;
    if to_number(to_char(p_date, 'YYYY')) not between 1900 and 2099 then
      return null;
    end if;
    l_eastern := eastern (to_number(to_char(p_date, 'YYYY')));
    if trunc(p_date) in (l_eastern - 2, l_eastern + 1, l_eastern + 39, l_eastern + 50) then
      return 0; -- eastern depentent bank holidays in lower saxony, Germany
    end if;
    return 1;
  end is_workday;
  -- This is what you are looking for:
  function workdays_between (p_date1 in date, p_date2 in date) return number as
    -- count number of workdays between p_date1 and p_date2 (both p_date1 and p_date2 included).
    l_count pls_integer := 0;
  begin
    for i in 0 .. p_date2 - p_date1 loop
      l_count := l_count + is_workday(p_date1 + i);
    end loop;
    return l_count;
  end workdays_between;
end;