Get the tags and hierarchy as output

Question

Hi gurus!
What I need to do is to get as output what tags i have in my xml. Also i need to know the hierarchy of these tags.
If my XML is this:
<root>
     <person>
          <name>Mary</name>
          <role>Queen</role>
     </person>
     <person>
          <name>George</name>
          <role>King</role>
     </person>
</root>I want my output to be something like:
Tag     Parent
root     null
person     root
name     person
role     personThe important thing here is that i don't know what tags are in the XML file and therefore i have to to it this way.
I don't have any previous knowledge of XML parsing in pl SQL but I´m assuming this is best done somehow with xmltypes. So far i have experimented with an xmltype instance but I'm stuck.
Any help is greatly appreciated!!
My version is 10.2.0.1.0

Answer 1

Hey,
We ended up redoing the whole thing with xmldom. Below are snippets of the final solution that got the processing time down from about one hour to 4 minutes for a 4Mb XML file.
procedure getChild(node xmldom.DOMNode, Id_parent number) is
  v_id          number;
  v_id_parent   number := Id_parent;
  nl_children   xmlDom.DOMNodeList;
  n             xmlDom.DOMNode;
  v_value       varchar2(3000);
  v_Name        varchar2(3000);
  begin
   nl_children := xmldom.getChildNodes(node);
  for i in 0..xmldom.getLength(nl_children)-1 loop
      n := xmldom.item(nl_children, i);
      v_Name := xmldom.getNodeName(n);
      v_id := lueXml.ELEMENT_ID;
      if xmldom.getNodeType(n) = xmldom.TEXT_NODE then
        v_value := xmldom.getNodeValue(n);
        update a_xml_taulu t set t.value = v_value
           where t.id = lueXml.ELEMENT_ID;
           commit;
      else
        lueXml.ELEMENT_ID := lueXml.ELEMENT_ID + 1;
        insert into a_xml_taulu (id, tag, parent, value)
           values (lueXml.ELEMENT_ID, v_Name, v_id_parent, '');
           commit;
        getChild(n, lueXml.ELEMENT_ID);
      end if;
  end loop;
end getChild;Which is called by
procedure readXMLfile is
  directory varchar2(100)     := 'testdir';
  filename  varchar2(100)     := 'File.xml';
  v_file         bfile    := bfilename(directory,filename);
  v_nclob        nclob;
  v_dest_offset  number   := 1;
  v_src_offset   number   := 1;
  v_lang_context integer  := DBMS_LOB.DEFAULT_LANG_CTX;
  v_warning      number;
  v_xmltype      xmltype;
  doc            xmldom.DOMDocument;
  nl             xmldom.DOMNodeList;
  n              xmldom.DOMNode;
  v_root_tag     varchar2(200);
  begin
    DELETE FROM a_xml_taulu;
    DELETE FROM a_temp_xml_storage;
    DELETE FROM a_temp_clob;
    commit;
  begin
    dbms_output.put_line('Starting insert of a_temp_clob at time '||to_char(sysdate, 'HH:MM:SS'));
    INSERT INTO a_temp_clob(id, file_name, xml_file, timestamp)
         VALUES (1001, filename, empty_clob(), sysdate)
      RETURNING xml_file INTO v_nclob;
    DBMS_LOB.fileopen(v_file);
    dbms_output.put_line('loading clob at '|| to_char(sysdate, 'HH:MM:SS'));
    DBMS_LOB.loadclobfromfile(dest_lob     => v_nclob,
                              src_bfile    =>  v_file,
                              amount       =>  DBMS_LOB.LOBMAXSIZE,
                              dest_offset  => v_dest_offset,
                              src_offset   => v_src_offset,
                              bfile_csid   => nls_charset_id('AL16UTF16LE'),
                              lang_context => v_lang_context,
                              warning      => v_warning);
    DBMS_LOB.close(v_file);            
    dbms_output.put_line('loaded clob at '||to_char(sysdate, 'HH:MM:SS'));
    INSERT INTO a_temp_clob(id, file_name, xml_file, timestamp)
        VALUES(1001, filename, v_nclob, sysdate);
    if v_warning > 0 then
        Dbms_Output.Put_Line ('Warning');
    end if;
  end;
  begin 
    dbms_output.put_line('Starting insert at time '||to_char(sysdate, 'HH:MM:SS'));
    INSERT INTO a_temp_xml_storage VALUES(xmltype(to_clob(v_nclob)));
    commit;
    dbms_output.put_line('Ending insert at time '||to_char(sysdate, 'HH:MM:SS'));
    select t.sys_nc_rowinfo$ into v_xmltype from a_temp_xml_storage t;
    luexml.ELEMENT_ID := 0;                                   -- this is a global variable
    doc := DBMS_XMLDOM.newDOMDocument(v_xmltype);
    nl := xmldom.getElementsByTagName(doc, '*');
    n := xmldom.item(nl, 0);
    v_root_tag := xmldom.getNodeName(n);
     insert into a_xml_taulu (id, tag, parent, value)
           values (lueXml.ELEMENT_ID, v_root_tag, null, '');
    lueXml.getChild(n, luexml.ELEMENT_ID);
    dbms_output.put_line('getChild iterations done at '||to_char(sysdate, 'HH:MM:SS'));
end; 
end readXMLfile;Im sure this version could be further optimized but it is fast enough already...
Thank you all for you help in this matter!