Getting error 462 - The remote server machine does not exist or is unavailable

Question

I have several modules that read and write data to and from Excel 2010 worksheets. I am noticing that the Excel process does not end aven though Excel is not running on my PC. It is like an orphan process. If I try running the Access module again I get the
message "error 462 - The remote server machine does not exist or is unavailable". Here is the code I am running. When I click the Debug button on the message box the line "rowNum = objXLAppln.Range("A" & Rows.Count).End(xlUp).Row"
is highlighted.
Option Compare Database
Option Explicit
Function ImportImportanceScores()
Dim RecSet As DAO.Recordset
Dim objXLAppln As Excel.Application
Set objXLAppln = New Excel.Application
Dim objWBook As Excel.Workbook
Dim rowNum As Variant
Dim i As Integer
Dim j As Integer
Dim StrPathFile As String, strFile As String, strPath As String
Dim strBrowseMsg As String, strInitialDirectory As String, strFilter As String
'show dialogue box
strBrowseMsg = "Select the EXCEL file:"
'set directory to load files from
strInitialDirectory = "C:\Bridge_CIP_Part-A_B\"
'run strFilter function
strFilter = ahtAddFilterItem(strFilter, "Excel Files (*.xlsx)", "*.xlsx")
StrPathFile = ahtCommonFileOpenSave(InitialDir:=strInitialDirectory, _
Filter:=strFilter, OpenFile:=True, _
DialogTitle:=strBrowseMsg, _
Flags:=ahtOFN_HIDEREADONLY)
If StrPathFile = "" Then
MsgBox "No file was selected.", vbOK, "No Selection"
Exit Function
End If
'Set Excel application object. Critical for macro to run properly. Do not change.
'Open workbook and worksheet to load data.
With objXLAppln
Set objWBook = objXLAppln.Workbooks.Open(StrPathFile)
objXLAppln.Visible = True
End With
Set RecSet = CurrentDb.OpenRecordset("Importance_Scores")
'Copy data from Excel cells to Access fields
objXLAppln.Sheets("Importance_Scores").Select
rowNum = objXLAppln.Range("A" & Rows.Count).End(xlUp).Row
objXLAppln.Range("A6").Select
'Add records to table from Excel
With RecSet
For i = 0 To rowNum - 6
RecSet.AddNew
RecSet.Fields("CIP_ID").value = objXLAppln.ActiveCell.Offset(i, 0).value
RecSet.Fields("Target_Timeframe_for_Construction").value = objXLAppln.ActiveCell.Offset(i, 2).value
RecSet.Fields("ImportanceFactor_TI-1").value = objXLAppln.ActiveCell.Offset(i, 21).value
RecSet.Fields("ImportanceFactor_TI-2").value = objXLAppln.ActiveCell.Offset(i, 22).value
RecSet.Fields("ImportanceFactor_TI-3").value = objXLAppln.ActiveCell.Offset(i, 23).value
RecSet.Fields("ImportanceFactor_TI-4").value = objXLAppln.ActiveCell.Offset(i, 24).value
RecSet.Fields("ProjectRank").value = objXLAppln.ActiveCell.Offset(i, 33).value
RecSet.Update
Next i
End With
'Close everything
RecSet.Close
objWBook.Close SaveChanges:=False
objXLAppln.Quit
Set RecSet = Nothing
Set objWBook = Nothing
Set objXLAppln = Nothing
End Function

Answer 1

In the line
    rowNum = objXLAppln.Range("A" & Rows.Count).End(xlUp).Row
Rows does not refer to objXLAppln or to objWBook. Change it to
    rowNum = objXLAppln.Range("A" & objWBook.Sheets("Importance_Scores").Rows.Count).End(xlUp).Row
Regards, Hans Vogelaar (http://www.eileenslounge.com)