GOS: How to display attachment?

Question

Hello,
I want to display the first attachment. I found the function GOS_ATTACHMENT_LIST_POPUP, but I haven't found a possibility to display an attachment directly. Does anybody know how to do this?
Please help.
Have a nice day. Bye.
Frank

Answer 1

This may not be the purist way of doing it, but hopefully it may help you along the way.
Jonathan
report zlocal_jc_sdn_gos_test.
tables:
  srgbtbrel.   "Relationships in GOS Environment
parameters:
*"Defaults here are an FI doc with GOS Note visible in FB03
  p_objkey                   like borident-objkey
                               default '100000120618312008',
  p_objtyp                   like borident-objtype
                               default 'BKPF'.
start-of-selection.
  perform display_attachment.
*&      Form  display_attachment
form display_attachment.
  data:
    l_objkey            type swo_typeid,
    lo_gos_service      type ref to cl_gos_document_service,
    ls_srgbtbrel        type srgbtbrel,
    lt_srgbtbrel        type srgbtbrel occurs 10.
*" Get a list of the links and choose one:
  select *
    into corresponding fields of table lt_srgbtbrel
    from srgbtbrel
    where instid_a = p_objkey
    and   typeid_a = p_objtyp
    and   reltype  = 'NOTE'.
*" Exit if no attachments found
  if lines( lt_srgbtbrel ) is initial.
    exit.
  endif.
*" Choose first one and set up the ident for the BOR
  sort lt_srgbtbrel by utctime. "put oldest top for this demo
  read table lt_srgbtbrel into ls_srgbtbrel index 1.
  l_objkey = ls_srgbtbrel-instid_b. "i.e. the Note's ID
  create object lo_gos_service.
  call method lo_gos_service->display_note
    exporting
      ip_note      = l_objkey
      ip_disp_html = 'X'.
*"Methods in cl_gos_document_service include:
*" DISPLAY_ATTACHMENT
*" DISPLAY_NOTE
*" DISPLAY_PERSONAL_NOTE
*" DISPLAY_URL
endform.                    "display_attachment