GUI_DOWNLOAD like SE16 format

Question

Hi all,
i have a requirement to build a report to download standard tables dinamically in foreground to a .txt file in the same format like going through SE16, displaying a standard table and go to System --> List --> Save --> Local File (format unconverted, Encoding 0000).
To achive this, i am using GUI_DOWNLOAD but i am not able to download it with the same format as through SE16.
Can I achive this with FM GUI_DOWNLOAD? What  parameters and values in the export i have to provide?
If i cant do this using this FM, what can i do to reach my requirement?
Thanks in advance.

Answer 1

Hi
You can try something like this:
PARAMETERS: P_TABLE TYPE DD02L-TABNAME.
DATA: DFIES_WA TYPE TABLE OF DFIES WITH HEADER LINE.
DATA: MY_TAB   TYPE REF TO DATA.
FIELD-SYMBOLS: <MY_TAB>   TYPE TABLE,
               <WA_TAB>   TYPE ANY,
               <WA_FIELD> TYPE ANY.
DATA: W_RECORD TYPE STRING,
      T_FILE   LIKE STANDARD TABLE OF W_RECORD,
      L_LINE(10000) TYPE C.
DATA: L_OFFSET      TYPE I,
      L_LEN         TYPE I,
      L_OUT         TYPE I.
START-OF-SELECTION.
  CALL FUNCTION 'DDIF_FIELDINFO_GET'
    EXPORTING
      TABNAME        = P_TABLE
    TABLES
      DFIES_TAB      = DFIES_WA
    EXCEPTIONS
      NOT_FOUND      = 1
      INTERNAL_ERROR = 2
      OTHERS         = 3.
  IF SY-SUBRC <> 0.
    EXIT.
  ENDIF.
  CREATE DATA MY_TAB TYPE TABLE OF (P_TABLE).
  ASSIGN MY_TAB->* TO <MY_TAB>.
  CHECK SY-SUBRC = 0.
  SELECT * INTO TABLE <MY_TAB>
    FROM (P_TABLE).
* Header
  LOOP AT DFIES_WA.
    L_LINE+L_OFFSET = '|'.
    L_OFFSET = L_OFFSET + 1.
* Output lenght
    L_LEN = STRLEN( DFIES_WA-FIELDNAME ).
    IF L_LEN > DFIES_WA-OUTPUTLEN.
      L_OUT = L_LEN.
    ELSE.
      L_OUT = DFIES_WA-OUTPUTLEN.
    ENDIF.
    L_LINE+L_OFFSET(L_OUT) = DFIES_WA-FIELDNAME.
    L_OFFSET = L_OFFSET + L_OUT.
  ENDLOOP.
  IF SY-SUBRC = 0.
    L_LINE+L_OFFSET = '|'.
    MOVE L_LINE TO W_RECORD.
    APPEND W_RECORD TO T_FILE.
  ENDIF.
* Data
  LOOP AT <MY_TAB> ASSIGNING <WA_TAB>.
    CLEAR L_LINE.
    CLEAR L_OFFSET.
    CLEAR W_RECORD.
    LOOP AT DFIES_WA.
      L_LINE+L_OFFSET = '|'.
      L_OFFSET = L_OFFSET + 1.
* Output lenght
      L_LEN = STRLEN( DFIES_WA-FIELDNAME ).
      IF L_LEN > DFIES_WA-OUTPUTLEN.
        L_OUT = L_LEN.
      ELSE.
        L_OUT = DFIES_WA-OUTPUTLEN.
      ENDIF.
* Value field
      ASSIGN COMPONENT DFIES_WA-FIELDNAME OF STRUCTURE <WA_TAB> TO <WA_FIELD>.
      MOVE <WA_FIELD> TO L_LINE+L_OFFSET(L_OUT).
      L_OFFSET = L_OFFSET + L_OUT.
    ENDLOOP.
    IF SY-SUBRC = 0.
      L_LINE+L_OFFSET = '|'.
      MOVE L_LINE TO W_RECORD.
      APPEND W_RECORD TO T_FILE.
    ENDIF.
  ENDLOOP.
  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      FILENAME = 'C:\temp\table_sap.txt'
      FILETYPE = 'ASC'
    TABLES
      DATA_TAB = T_FILE.