Help setting up Applescript to process with a batch of files.

Question

Hello everyone!
A couple of days ago I posted here about needing an Applescript to be able to parse large text files into smaller ones. A lovely contributor, twtwtw, helped me out and came up with this script:
set f to choose file with prompt "Choose the file to parse."
tell application "Finder"
    set fName to name of f
    -- the following line assumes that the file name has a three character extension, like '.txt'
    set foldName to text 1 thru -5 of fName
    set fold to (make new folder at (path to documents folder from user domain) with properties {name:foldName}) as text
end tell
set fp to open for access f
set bigText to read fp
close access fp
set parsingText to "All Rights Reserved"
set parsedList to tid(bigText, parsingText)
-- the following line requires that the file name be exactly in the form "<prefix>_<suffix>" with only one underscore
set {prefix, suffix} to tid(fName, "_")
repeat with i from 1 to count of parsedList
    set newFName to prefix & "_a" & i & "_" & suffix
    set fp to open for access (fold & newFName) with write permission
    -- uncomment the following line if you need to overwrite old files, otherwise it will append
    -- set EOF of fp to 0
    write ((item i of parsedList & parsingText) as text) to fp
    close access fp
end repeat
on tid(input, delim)
    -- a subroutine to handle text item delimiters. Useful tool, but so danged wordy.--
    set {oldTID, my text item delimiters} to {my text item delimiters, delim}
    if class of input is list then
        set output to input as text
    else
        set output to text items of input
    end if
    set my text item delimiters to oldTID
    return output
end tid
It turns out however, that I have about 500 of these large files that need parsing, so I was wondering if there might be a way to modify the script by allowing more than one input file, so that it would repeat the parsing action for all input files passed to it.
Can anyone help?

Answer 1

try this:
set f to choose folder with prompt "Choose the root folder containing your files."
traverseFolder(f)
on traverseFolder(fold)
     tell application "System Events"
         set containedItems to every disk item of fold whose visible is true
         repeat with thisItem in containedItems
               if class of thisItem is folder then
                   my traverseFolder(thisItem)
               else if type identifier of thisItem contains "plain-text" then
                   my processFile(thisItem, fold)
               end if
         end repeat
     end tell
end traverseFolder
on processFile(thisFile, itsFolder)
     tell application "System Events"
         set fName to name of thisFile
  -- the following line assumes that the file name has a three character extension, like '.txt'
         set foldName to text 1 thru -5 of fName
         set newFold to path of (make new folder at end of itsFolder with properties {name:foldName})
     end tell
     set fp to open for access thisFile
     set bigText to read fp
  close access fp
     set parsingText to "All Rights Reserved"
     set parsedList to tid(bigText, parsingText)
  -- the following line requires that the file name be exactly in the form "<prefix>_<suffix>" with only one underscore
     set {prefix, suffix} to tid(fName, "_")
     repeat with i from 1 to count of parsedList
         set newFName to prefix & "_a" & i & "_" & suffix
         set fp to open for access (newFold & newFName) with write permission
  -- uncomment the following line if you need to overwrite old files, otherwise it will append
  -- set EOF of fp to 0
  write ((item i of parsedList & parsingText) as text) to fp
  close access fp
     end repeat
end processFile
on tid(input, delim)
  -- a subroutine to handle text item delimiters. Useful tool, but so danged wordy.--
     set {oldTID, my text item delimiters} to {my text item delimiters, delim}
     if class of input is list then
         set output to input as text
     else
         set output to text items of input
     end if
     set my text item delimiters to oldTID
     return output
end tid
I changed to system events for efficiency reasons (the Finder can get bogged down with too much scripting).  the only place you might run into issues is line 11, where it says else if type identifier of thisItem….  that might miss files if they have odd type identifiers (though it should get most plain-text files).  I only put that if statement in there to keep from processing spurious files that might be in the folders - you can replace that whole line with a simple else if you find it's gumming up the works.