[HELP] VBA Currency NumberFormat Error - Excel

Question

[HELP] VBA Currency NumberFormat Error - Excel
Hello,
I've a worksheet with many cells formated as currency and i want modify the currency format through a combobox,
First i use this code to get the inicial currency type/format,
Private Sub ComboBox1_DropButtonClick()
inicial = Me.ComboBox1.Value
Select Case inicial
Case "EUR"
oldFormat = "#.##0 €"
Case "GBP"
oldFormat = "[$£-809]#.##0"
Case "USD"
oldFormat = "#.##0 [$USD]"
End Select
End Sub
The oldformat variable is a global variable,
Public oldformat As String
After that i want to do a find using oldformat variable and a replace using a newformat variable,
Private Sub ComboBox1_Change()
Dim ws As Worksheet
Dim newFormat As String
'On Error Resume Next
newValue = Me.ComboBox1.Value
Select Case newValue
Case "EUR"
newFormat = "#.##0 €"
Case "GBP"
newFormat = "[$£-809]#.##0"
Case "USD"
newFormat = "#.##0 [$USD]"
End Select
'Set rNextCell = Application.FindFormat
For Each ws In ActiveWorkbook.Worksheets
Application.FindFormat.Clear
Application.FindFormat.NumberFormat = oldFormat
Application.ReplaceFormat.Clear
Application.ReplaceFormat.NumberFormat = newFormat
ws.Cells.Replace What:="", Replacement:="", LookAt:=xlPart, SearchOrder _
:=xlByRows, MatchCase:=False, SearchFormat:=True, ReplaceFormat:=True
Next ws
End Sub
I read the new value through the user choice on the combobox.
But this not work at all, the variables oldformat and newformat receive the correct values but i got a error on,
Run-time error '1004': Application-defined or object-defined error
Application.FindFormat.NumberFormat = oldformat
Application.ReplaceFormat.NumberFormat = newFormatIs there any way to pass the newformat and oldformat value to the Numberformat property?
Or someone have another away to do this?
Link for exemple file,
https://www.dropbox.com/s/sdyfbddxy08pvlc/Change_Currency.xlsm
I apreciate any help, i m a little bit new on .
I apologize if there are any errors in English, is not my natural language.

Answer 1

The number formats must already be present in the workbook, otherwise you'll get the error that you mention.
The code for US$ is [$$-409]
Here is the code:
Public oldFormat As String
Private Sub ComboBox1_Change()
Dim ws As Worksheet
Dim newValue As String
Dim newFormat As String
newValue = Me.ComboBox1.Value
Select Case newValue
Case "EUR"
newFormat = "#,##0 €"
Case "GBP"
newFormat = "[$£-809]#,##0"
Case "USD"
newFormat = "#,##0 [$$-409]"
End Select
Application.FindFormat.Clear
Application.FindFormat.NumberFormat = oldFormat
Application.ReplaceFormat.Clear
Application.ReplaceFormat.NumberFormat = newFormat
For Each ws In ActiveWorkbook.Worksheets
ws.Cells.Replace What:="", Replacement:="", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, _
SearchFormat:=True, ReplaceFormat:=True
Next ws
End Sub
Private Sub ComboBox1_DropButtonClick()
Dim inicial As String
inicial = Me.ComboBox1.Value
Select Case inicial
Case "EUR"
oldFormat = "#,##0 €"
Case "GBP"
oldFormat = "[$£-809]#,##0"
Case "USD"
oldFormat = "#,##0 [$$-409]"
End Select
End Sub
See https://www.dropbox.com/s/ax20vnmjpjny3h6/Change_Currency.xlsm
Regards, Hans Vogelaar (http://www.eileenslounge.com)