Help with a script (what am I doing wrong)

Question

tell application "Finder"
set theFolder to (choose folder with prompt "choose the user folder") as Unicode text
set newFolder to make new folder at theFolder as Unicode text with properties {name:"test folder"}
set targetFolder to newFolder
move entire contents of (theFolder & "Library:Preferences") to targetFolder
end tell
error "Can’t get entire contents of \"Macintosh HD:Users:username:Library:Preferences\"." number -1728 from «class ects» of "Macintosh HD:Users:username:Library:Preferences"
also I would like the new folder in Library not user folder

Answer 1

I had some time to give the connected volume stuff another look, so I tweaked the script a little. This latest version will handle getting the users from local or connected volumes as well as connected accounts. I threw in some labels in the choice dialog so you can see what the volumes are, and changed the time stamp a little to avoid using either the POSIX or Finder path delimiters.
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #DAFFB6;
overflow: auto;"
title="this text can be pasted into the Script Editor">
-- remove user preferences to a backup folder
set theUsers to {}
repeat with aDisk in (get list disks)
set aDisk to contents of aDisk
tell application "System Events"
if (local volume of disk aDisk) then -- get users from local disks
if (startup of disk aDisk) then
set label to "[Startup Volume] "
else
set label to "[Local Volume] "
end if
repeat with aUser in paragraphs of (do shell script "ls '/Volumes/" & aDisk & "/Users'")
if aUser is not in {"Shared"} then set the end of theUsers to (label & aDisk & "/Users/" & aUser)
end repeat
end if
try
if (server of disk aDisk is not missing value) then -- get users from connected disks
try
repeat with aUser in paragraphs of (do shell script "ls '/Volumes/" & aDisk & "/Users'")
if aUser is not in {"Shared"} then set the end of theUsers to ("[Server Volume] " & aDisk & "/Users/" & aUser)
end repeat
on error errmess -- get connected user
log errmess
set the end of theUsers to ("[Server " & (server of disk aDisk) & "] " & aDisk)
end try
end if
end try
end tell
end repeat
set theChoice to (choose from list theUsers with title "Move preferences to backup" with prompt "Select an account to move user preferences:" with empty selection allowed) as text
if the result is in {"false", ""} then return -- no selection
set theChoice to "/Volumes/" & text ((offset of "] " in theChoice) + 2) thru -1 of theChoice -- strip off the volume labels
set theSource to (theChoice & "/Library/Preferences") as POSIX file as text as alias
set theDestination to (theChoice & "/Library") as POSIX file as text as alias
tell ((current date) as «class isot» as string) to set timeStamp to (text 6 thru 7) & "-" & (text 9 thru 10) & "-" & (text 3 thru 4) & space & (text 12 thru 13) & (text 15 thru 16) -- ISO time = yyyy-MM-ddThh:mm:ss
set theName to "Preferences copy " & timeStamp
try
set targetFolder to ((theDestination as text) & theName) as alias
on error errmess
log errmess
tell application "Finder" to make new folder at theDestination with properties {name:theName}
set targetFolder to the result as alias
end try
tell application "Finder" to move items of theSource to targetFolder
</pre>