How can I capture a semi transparent window?

Question

Hello all
I am trying to grab an image of a semi transparent window into a bitmap. I have tried using both CopyFromScreen and BitBlt using the window handle but in both cases all I get is the image from behind the window I want to catch, it's like the semi transparent
window is completely invisible to both capture methods. Is there any way I can capture the window I want?
Thanks
Rich

Answer 1

Here is an example. You can try it in a new form project with 1 Button and 1 PictureBox added to the form. As i said, it is just an example so, when it is run the form will be partialy transparent. Click the button and it will capture the whole screen including
your transparent form. Then it will set the forms opacity back to 1.0 so you can see that the transparent form was captured in the image.
 You will need to set it up to be used in a practical way. This is just a quick test example.
Imports System.Runtime.InteropServices
Public Class Form1
Private Const CAPTUREBLT As Integer = &H40000000
Private Const SRCCOPY As Integer = &HCC0020
<DllImport("gdi32.dll", EntryPoint:="BitBlt")> _
Private Shared Function BitBlt(ByVal hdcDest As IntPtr, ByVal nXDest As Integer, ByVal nYDest As Integer, ByVal nWidth As Integer, ByVal nHeight As Integer, ByVal hdcSrc As IntPtr, ByVal nXSrc As Integer, ByVal nYSrc As Integer, ByVal dwRop As UInteger) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("user32.dll", EntryPoint:="GetDC")> Private Shared Function GetDC(ByVal hWnd As System.IntPtr) As System.IntPtr
End Function
<DllImport("user32.dll", EntryPoint:="ReleaseDC")> Private Shared Function ReleaseDC(ByVal hWnd As System.IntPtr, ByVal hDC As System.IntPtr) As Integer
End Function
Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
'set this form so it is partialy transparen. Just to show it was captured for this example
Me.Opacity = 0.5
PictureBox1.SizeMode = PictureBoxSizeMode.Zoom
End Sub
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
'if the picturebox has an Image the Dispose it first
If PictureBox1.Image IsNot Nothing Then PictureBox1.Image.Dispose()
'define the rectangle area of the screen to capture (whole screen in this case)
Dim CaptureRectangle As Rectangle = Screen.PrimaryScreen.Bounds
'Assign the new image captured from the screen to the picturebox image
PictureBox1.Image = CaptureScreenImage(CaptureRectangle)
'just so you can see the image better set the form`s opacity back to 1.0
Me.Opacity = 1.0
End Sub
Private Function CaptureScreenImage(ByVal rect As Rectangle) As Bitmap
Dim scrnHdc As IntPtr = GetDC(IntPtr.Zero)
Dim bmp As New Bitmap(rect.Width, rect.Height)
Using grx As Graphics = Graphics.FromImage(bmp)
Dim grxHdc As IntPtr = grx.GetHdc()
BitBlt(grxHdc, 0, 0, rect.Width, rect.Height, scrnHdc, rect.X, rect.Y, SRCCOPY Or CAPTUREBLT)
grx.ReleaseHdc(grxHdc)
ReleaseDC(IntPtr.Zero, scrnHdc)
End Using
Return bmp
End Function
End Class
If you say it can`t be done then i`ll try it