How Do I Clear the KeepWithNext Flag on Every Pragraph in a Table Except For the One in Table Header?

Question

Howdy,
I am trying to clear the KeepWithNext flag for all the paragraphs in every table in the document but the ones in table headings.
What's the best way to do that.
At the moment I only have the following script that clears the KeepWithNext flag for every paragraph in every table.
Sub ClearKeepWNext()
Dim t As Table
For Each t In ActiveDocument.Tables
t.Range.ParagraphFormat.KeepWithNext = False
t.AutoFitBehavior (wdAutoFitContent)
Next
End Sub
This results in table headers split so that many tables have only the table header at the bottom of the page where all other table rows start on the text page.
What would be the best way to fix that?
Thank you in advance.
Well this is the world we live in And these are the hands we're given...

Answer 1

Try:
Sub ClearKeepWNext()
Dim Tbl As Table, i As Long
For Each Tbl In ActiveDocument.Tables
  With Tbl
    .Range.ParagraphFormat.KeepWithNext = False
    For i = 1 To .Rows.Count
      With .Rows(i)
        If .HeadingFormat = True Then
          .Range.ParagraphFormat.KeepWithNext = True
        Else
          Exit For
        End If
      End With
    Next
  End With
Next
End Sub
If the tables only have a single heading row, you could instead use:
Sub ClearKeepWNext()
Dim Tbl As Table
For Each Tbl In ActiveDocument.Tables
  With Tbl
    .Range.ParagraphFormat.KeepWithNext = False
    With .Rows(1)
      If .HeadingFormat = True Then
        .AllowBreakAcrossPages = False
      End If
    End With
  End With
Next
End Sub
Cheers
Paul Edstein
[MS MVP - Word]