How do I edit this script (newbie)

Question

Editing a script
I found a script that creates a reminder event based upon the birthdays of my contacts in Address Book. It looks forward one week at a time.
I'm not familiar with creating scripts. How would I edit this to do the following (if possible)
1- I set up a contact list in Address Book for only those people whose birthdays I want to be reminded of. Is it possible to have this script only look through this contact list, not every contact.
2- Can it also be set up to delete the previously set events (so that the only events that appear are the ones for the ensuing week)
3- Can it be set up to remind me of anniversaries also? How would I edit it? (I tried to find and replace the term birthday with anniversary, but all it did was notify me of forthcoming week's birthdays but called them anniversaries)
Thanks!
===============
birthdayAlert.scpt
User set variables
set numberDaysNotice to 1 -- how many days before the birthday to alert you, 0 is that day
set timeOfNotification to 5 -- the hour you want the notification
set selectedCalender to "Birthday Reminders" -- the calender in iCal you want to add the events to
Setup
set birthdayPeople to {}
set birthdayDates to {}
Get the current date & next week
set today to current date
set nextWeek to today + (60 * 60 * 24 * 7)
Loop through everyone in the Address Book
tell application "Address Book"
set peopleArray to the name of every person
repeat with i from 1 to count of peopleArray
set thisPerson to person i
set thisBirthday to birth date of thisPerson
Check if they've got a birthday entered on their card
if thisBirthday is not equal to (missing value) then
set year of thisBirthday to year of (current date) -- otherwise it uses their birth year
See if it's in the next week
if (thisBirthday is greater than today) and (thisBirthday is less than nextWeek) then
set thisBirthday_day to day of thisBirthday
set thisBirthday_month to month of thisBirthday
Add them to our list
set birthdayPeople to birthdayPeople & name of thisPerson
set birthdayDates to birthdayDates & birth date of thisPerson
end if
end if
end repeat
end tell
If we have birthday's go into iCal and add the alerts
if (count of birthdayPeople) is greater than 0 and ((count of birthdayPeople) is equal to (count of birthdayDates)) then
tell application "iCal"
tell calendar selectedCalender
repeat with i from 1 to count of birthdayPeople
set thisDate to item i of birthdayDates
set year of thisDate to year of today
set time of thisDate to (60 * 60) * timeOfNotification
set day of thisDate to (day of thisDate) - numberDaysNotice
set thisEvent to make new event at end with properties {description:"", summary:(item i of birthdayPeople) & "'s Birthday", location:"", start date:thisDate, end date:thisDate + 15 * minutes}
tell thisEvent
make new display alarm at end with properties {trigger interval:0}
end tell
end repeat
end tell
end tell
end if

Answer 1

1- I set up a contact list in Address Book for only those people whose birthdays I want to be reminded of. Is it possible to have this script only look through this contact list, not every contact.
Sure - if you created a specific group of the people you want to track then just change the line:
set peopleArray to the name of every person
to:
set peopleArray to the name of every person of group "Birthdays"
(or whatever group name you used). You see, as written your script just grabs everyone's name as opposed to just the names of people in the specific group.
2- Can it also be set up to delete the previously set events (so that the only events that appear are the ones for the ensuing week)
Yes, but that's a little trickier since you need some way to denote which events are birthday events vs. other events from last week. If you're using a specific calendar for this then you could just delete existing events in that calendar, or you could implement a minor change to the way you create events - use the description to identify this is one of your auto-created birthday alarms:
set thisEvent to make new event at end with properties {description:"birthday", summary:(item i of birthdayPeople) & "'s Birthday", location:"", start date:thisDate, end date:thisDate + 15 * minutes}
So now the events will have a specific description, so it's easy to start your new script off with a line that deletes existing 'birthday" events, via:
tell application "iCal"
  delete every event of calendar selectedCalendar whose description = "birthday"
end tell
(you can nix the '... whose description = "birthday"' element if you just want to delete all existing events in the calendar).
3- Can it be set up to remind me of anniversaries also? How would I edit it? (I tried to find and replace the term birthday with anniversary, but all it did was notify me of forthcoming week's birthdays but called them anniversaries)
Sure, that's because you specifically ask Address Book for birthdays:
set thisBirthday to birth date of thisPerson
To track anniversaries you need to ask Address Book for different data. This one's a little tricker since anniversaries are tracked via the custom date element, so you'd need something like:
set anniversaryList to {}
tell application "Address Book"
  repeat with eachPerson in (get every person) -- add 'of group "anniversaries' if you use a specific group
    repeat with eachDate in eachPerson's custom dates
      if label of eachDate = "anniversary" then
        -- this person has an Anniversary set, so add your code here to check if eachDate is in the next week if it is:
        copy eachPerson to end of anniversaryList
      end if
    end repeat
  end repeat
end tell
At the end of this you'll have a list of people whose anniversary is upcoming and you can duplicate your iCal code to add anniversary events in addition to birthdays.