How do I make a good menu list for a launcher? (Automator)

Question

First of all, sorry... I know this isn't exactly a Dev topic, but I didn't know what community to put it in. I currently have a simple Automator program that:
1. Launches
2. Finds all items with the Tag:Games
3. Presents said items in a list to be picked from
4. Launches the one that is picked
What I am wondering is how to make a better looking selection window. At the moment, it shows the file paths to the .exe's (I use this for my WINE games), and all of them are selected by default, and I obviously don't want to launch all of them at once, and the file path looks a bit ugly and is hard to find the right game. I just need a way to make a simple window where you click on the right application, and it launches (In automator, preferably).

Answer 1

If you put the following into an Automator Run AppleScript action it may help:
on run
          set name_list to {}
          set path_list to {}
          set {old_tids, AppleScript's text item delimiters} to {AppleScript's text item delimiters, "."}
          repeat with each_item in (every paragraph of (do shell script "mdfind \"kMDItemUserTags == Games\""))
                    set the_file to POSIX file each_item
                    copy the_file to end of path_list
                    tell application "Finder" to set file_name to text item 1 of (name of file the_file as text)
                    copy file_name to end of name_list
          end repeat
          set AppleScript's text item delimiters to old_tids
          set game_chosen to item 1 of (choose from list name_list with title "Choose a game" with prompt "Choose a game:" without multiple selections allowed)
          repeat with x from 1 to (count name_list)
                    if game_chosen = item x of name_list then exit repeat
          end repeat
          tell application "Finder" to open file (item x of path_list)
end run