How does this LINQ query work with Option Infer Off?

Question

How should value and filtered be declared?  It doesn't work when I turn Option Infer Off.  Originally, it worked with Option Infer On. There was no Dim statement on the first line, but the Dim keyword was placed before the
filtered = line.  As soon as I turned Option Infer Off, all sorts of errors showed up.  How should the code be adjusted?  (Option Strict is On.)
Dim element, value, filtered As Integer
Dim values() As Integer = {2, 9, 5, 0, 3, 7, 1, 4, 8, 6}
filtered =
From value In values
Where (value > 4)
Select value
For Each element In filtered
Console.Write(element & " ")
Next
Solitaire

Answer 1

Hi Solitaire,
the Option Infer Off version would be:
Option Strict On
Option Infer Off
Imports System
Imports System.Collections.Generic
Imports System.Linq
Public Class Class1
Public Shared Sub LinqWithNoInfer()
Dim values() As Integer = {2, 9, 5, 0, 3, 7, 1, 4, 8, 6}
' compiled to
' filtered = values.Where(Function(value As Integer) value > 4).Select(Function(value As Integer) value)
value)
Dim filtered As IEnumerable(Of Integer) =
From value In values
Where (value > 4)
Select value
For Each element As Integer In filtered
Console.Write(element & " ")
Next
End Sub
End Class
The type for filtered is determined by the Select statement, that is
Enumerable.Select, and will return an
IEnumerable(Of T) and T is an Integer here.
Option Infer looks for the return value of Select and will give the same result.
Note: For Lambda Expressions Option Infer Off is ignored and the type is inferred - both are valid:
filtered = values.Where(Function(value) value > 4).Select(Function(value) value)
filtered = values.Where(Function(value As Integer) value > 4).Select(Function(value As Integer) value)
Regards, Elmar