How to find ANGLE B/W two edges in Oracle Spatial

Question

How to find ANGLE B/W two edges in Oracle Spatial. I have two edge connected on same node. I wanted to know the angle betwwn them. Can somebody help me out????

Answer 1

Ok. My first example was an approximation. The farther you get north or south of equator, the more inacurate it gets.
This one should do the trick with some degree of accuracy.
declare
  PI constant number := 3.14159265358979;
  g1 sdo_geometry;
  g2 sdo_geometry;
  g3 sdo_geometry;
  angle1 number;
  angle2 number;
  FUNCTION POINT(P_LAT  IN number
                ,P_LONG IN number)
    RETURN MDSYS.SDO_GEOMETRY IS
  BEGIN
    -- we load both the ordinate array and the point type because some spatial functions show inconsistent behavior
    -- it is not important for this example, just something to be aware of
    return(mdsys.sdo_geometry(2001,8307 -- WGS84
                             ,mdsys.sdo_point_type(p_long,p_lat,null)
                                                  ,mdsys.sdo_elem_info_array(1,2,1)
                                                  ,mdsys.sdo_ordinate_array(p_long,p_lat)));
  END;
begin
  -- For the example, project in WGS84
  -- g1,g2,g3 could also come straight out of the database as sdo_geometry
  g1 := point(50, 7);          -- Point A
  g2 := point(51, 7);          -- Point B
  g3 := point(50,10);          -- Point C
  angle1 := atan2(g2.sdo_point.x - g1.sdo_point.x,
                  g2.sdo_point.y - g1.sdo_point.y);
  angle2 := atan2(g3.sdo_point.x - g1.sdo_point.x,
                  g3.sdo_point.y - g1.sdo_point.y);
  -- depending on rotation and where we are on the planet, adjustments may be needed
  if angle1 < 0      then angle1 := angle1 + 2 * PI; end if;
  if angle2 < 0      then angle2 := angle2 + 2 * PI; end if;
  if angle2 < angle1 then angle2 := angle2 + 2 * PI; end if;
  dbms_output.put_line('Angle between the lines A-B and A-C: '||
                       round(sdo_util.convert_unit(angle2-angle1,'Radian','Degree'),1));
end;
Angle between the lines A-B and A-C: 90