How to list all documents that has linked a image file?

Question

Hi everyone,
I'd like to know if there's a way to find all linked file to a file: i have a logo image that a lot of inDesign files have linked to it and i'd like to find all those inDesign files.
I know that Bridge CS6 can list all linked files of a .indd file but i'd like the opposite
Regards,
Snowblood13x

Answer 1

You might be able to do it via scripting. If you have to search an entire volume it would be impractical, but something like this AppleScript would open all of the ID files inside of a chosen folder and its sub folders. Once the ID file is open it could check for a specific link and if it exists leave the file open otherwise close:
global mylinkname
--change YourLinkNameHere to the logo link's name
set mylinkname to "YourLinkNameHere"
tell application "Finder"
    activate
    set the thisFolder to (choose folder with prompt "Choose a folder. The extension of all files inside will be hidden.")
    my ProcessFolder(thisFolder)
    tell application "Adobe InDesign CS6"
        activate
        display dialog "Done"
    end tell
end tell
on ProcessFolder(thisFolder)
    set theseItems to list folder thisFolder without invisibles
    repeat with i from 1 to count of theseItems
        set thisItem to alias ((thisFolder as text) & (item i of theseItems))
        set the iteminfo to info for thisItem
        if folder of the iteminfo is true then
            ProcessFolder(thisItem)
        else
            ProcessItem(thisItem)
        end if
    end repeat
end ProcessFolder
on ProcessItem(thisalias)
    tell application "Finder"
        if creator type of file thisalias is "InDn" and kind of file thisalias is not "InCopy® Lock File" then
            tell application "Adobe InDesign CS6"
                activate
                --set user interaction level of script preferences to never interact
                open thisalias
                set llist to name of every link of active document
                if mylinkname is not in llist then
                    tell active document
                        close
                    end tell
                end if
                --set user interaction level of script preferences to interact with all
            end tell
        end if
    end tell
end ProcessItem