How to pass a col of pl/sql tab to a parametrized cursor?

Question

Hi,
I'm getting this error constantly:
Error on line 1
declare
j number :=1;
cursor f
ORA-06550: line 9, column 20:
PLS-00103: Encountered the symbol "TABLE" when expecting one of the following:
constant exception <an identifier>
<a double-quoted delimited-identifier> table LONG_ double ref
char time timestamp interval date binary national character
nchar
Code Snippet:
declare
j number :=1;
cursor firstquery (c_item in varchar2) is
SELECT SEARCH, NAME, ID FROM tablename
WHERE name LIKE c_item;
first_rec_tbl_type is table of firstquery%rowtype index by binary_integer;
first_rec_tbl first_rec_tbl_type;
type act_str_tbl_type is table of varchar2(50) index by binary_integer;
act_put_str_tbl act_str_tbl_type;
begin
this is executing fine as i have executed it as a standalone script also
act_put_str_tbl table has values here.passing these to below:
----------------------------------- i guess the problem lies here------------------------
     begin
          dbms_output.put_line('reached second begin');
For i in act_put_str_tbl.first..act_put_str_tbl.last
     loop
     dbms_output.put_line('inside loop of second begin');
     open firstquery(act_put_str_tbl(i));
          loop
          fetch firstquery into first_rec_tbl(j);
          j:=j+1;
          exit when firstquery%notfound or firstquery is null;
          end loop;
     close firstquery;
     end loop;
How to use parametrized cursor with PL/SQL table, any help is appreciated in the above snippet.
Thanks

Answer 1

Satyaki_De wrote:
first_rec_tbl_type is table of firstquery%rowtype index by binary_integer;Create this type in side any package like ->
create or replace package patch_array
is
first_rec_tbl_type is table of firstquery%rowtype index by pls_integer;
end;But, you have to use explicit record type instead of firstquery%rowtype here.
And, then refer this type inside your parametrized cursor to use that properly, that might solve your current problem - i guess.
So, you cursor should look something like this ->
cursor firstquery (c_item in patch_array.first_rec_tbl_type)
is
SELECT SEARCH, NAME, ID
FROM tablename
WHERE name LIKE c_item; N.B.:Not Tested...
Regards.
Satyaki De.
Edited by: Satyaki_De on Dec 28, 2008 1:32 AM??? No package is needed:
SQL> declare
  2      j number := 1;
  3      cursor firstquery(
  4                        c_item in varchar2
  5                       )
  6        is
  7          SELECT  ename,
  8                  sal
  9            FROM  emp
10            WHERE ename LIKE c_item;
11      type first_rec_tbl_type is table of firstquery%rowtype index by binary_integer;
12      first_rec_tbl first_rec_tbl_type;
13      type act_str_tbl_type is table of varchar2(50) index by binary_integer;
14      act_put_str_tbl act_str_tbl_type;
15  begin
16      act_put_str_tbl(1) := 'S%';
17      act_put_str_tbl(2) := '%L%';
18      act_put_str_tbl(3) := 'KING';
19      begin
20          dbms_output.put_line('reached second begin');
21          For i in 1..nvl(act_put_str_tbl.count,0) loop
22            dbms_output.put_line('inside loop of second begin');
23            dbms_output.put_line('act_put_str_tbl(' || i || ') = ' || act_put_str_tbl(i));
24            open firstquery(act_put_str_tbl(i));
25            loop
26              fetch firstquery into first_rec_tbl(j);
27              exit when firstquery%notfound;
28              dbms_output.put_line('first_rec_tbl(' || j || ').ename = ' || first_rec_tbl(j).enam
e);
29              dbms_output.put_line('first_rec_tbl(' || j || ').sal = ' || first_rec_tbl(j).sal);
30              j:=j+1;
31            end loop;
32            close firstquery;
33          end loop;
34      end;
35  end;
36  /
reached second begin
inside loop of second begin
act_put_str_tbl(1) = S%
first_rec_tbl(1).ename = SMITH
first_rec_tbl(1).sal = 800
first_rec_tbl(2).ename = SCOTT
first_rec_tbl(2).sal = 3000
inside loop of second begin
act_put_str_tbl(2) = %L%
first_rec_tbl(3).ename = ALLEN
first_rec_tbl(3).sal = 1600
first_rec_tbl(4).ename = BLAKE
first_rec_tbl(4).sal = 2850
first_rec_tbl(5).ename = CLARK
first_rec_tbl(5).sal = 2450
first_rec_tbl(6).ename = MILLER
first_rec_tbl(6).sal = 1300
inside loop of second begin
act_put_str_tbl(3) = KING
first_rec_tbl(7).ename = KING
first_rec_tbl(7).sal = 5000
PL/SQL procedure successfully completed.
SQL> To OP. It is better to use BULK COLLECT:
SQL> declare
  2      cursor firstquery(
  3                        c_item in varchar2
  4                       )
  5        is
  6          SELECT  ename,
  7                  sal
  8            FROM  emp
  9            WHERE ename LIKE c_item;
10      type first_rec_tbl_type is table of firstquery%rowtype index by binary_integer;
11      first_rec_tbl first_rec_tbl_type;
12      type act_str_tbl_type is table of varchar2(50) index by binary_integer;
13      act_put_str_tbl act_str_tbl_type;
14  begin
15      act_put_str_tbl(1) := 'S%';
16      act_put_str_tbl(2) := '%L%';
17      act_put_str_tbl(3) := 'KING';
18      begin
19          dbms_output.put_line('reached second begin');
20          For i in 1..nvl(act_put_str_tbl.count,0) loop
21            dbms_output.put_line('inside loop of second begin');
22            dbms_output.put_line('act_put_str_tbl(' || i || ') = ' || act_put_str_tbl(i));
23            open firstquery(act_put_str_tbl(i));
24            fetch firstquery bulk collect into first_rec_tbl;
25            for j in 1..nvl(first_rec_tbl.count,0) loop
26              dbms_output.put_line('first_rec_tbl(' || j || ').ename = ' || first_rec_tbl(j).enam
e);
27              dbms_output.put_line('first_rec_tbl(' || j || ').sal = ' || first_rec_tbl(j).sal);
28            end loop;
29            close firstquery;
30          end loop;
31      end;
32  end;
33  /
reached second begin
inside loop of second begin
act_put_str_tbl(1) = S%
first_rec_tbl(1).ename = SMITH
first_rec_tbl(1).sal = 800
first_rec_tbl(2).ename = SCOTT
first_rec_tbl(2).sal = 3000
inside loop of second begin
act_put_str_tbl(2) = %L%
first_rec_tbl(1).ename = ALLEN
first_rec_tbl(1).sal = 1600
first_rec_tbl(2).ename = BLAKE
first_rec_tbl(2).sal = 2850
first_rec_tbl(3).ename = CLARK
first_rec_tbl(3).sal = 2450
first_rec_tbl(4).ename = MILLER
first_rec_tbl(4).sal = 1300
inside loop of second begin
act_put_str_tbl(3) = KING
first_rec_tbl(1).ename = KING
first_rec_tbl(1).sal = 5000
PL/SQL procedure successfully completed.
SQL> SY.
Edited by: Solomon Yakobson on Dec 27, 2008 12:32 PM