How to protect Excel cells while allowing VBA to modify them?

Question

I want to allow users to modify inputs in some Unlocked cells and have the other cells update accordingly. I also want to prevent users from clobbering those other cells, so those are Locked.
Protect Sheet allows ordinary formulas in Locked cells to execute but, by default, prevents VBA functions from executing when their input cells are modified. So, after consulting the
Excel 2013 developer reference's descriptions of the Worksheet.Protect method and
Worksheet object, I added these statements to my initialization routine:
Worksheets(1).Activate
ActiveSheet.Protect "", UserInterfaceOnly = True
The 2nd statement enables Protect Sheet with a null password successfully, but the UserInterfaceOnly setting isn't having the effect I expected, i.e., allowing the VBA functions to execute when their input cells are changed. (I've noticed it seems to enable
the Allow Users to Edit Objects protection option.)
I also tried := True, but that doesn't help.

Answer 1

The function fails because you cannot change characteristics of a chart in a worksheet function. A worksheet function can only return a value to the cell that contains the formula.
You can use the Worksheet_Change event to modify the chart instead. The function can be simplified to
Function Show_RGB(Y, u, v, Swatch) As Variant
Dim R As Single, G As Single, B As Single
On Error GoTo ErrHandler
R = R_from_Yuv(Y, u, v)
G = G_from_Yuv(Y, u, v)
B = B_from_Yuv(Y, u, v)
Show_RGB = Array(R, G, B) ' Allow <0 and >255 in spreadsheet
ExitHandler:
Exit Function
ErrHandler:
MsgBox Err.Description, vbExclamation
Resume ExitHandler
End Function
The Worksheet_Change event procedure in the worksheet module:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim R As Single, G As Single, B As Single, Swatch As Integer
Dim rng As Range
On Error GoTo ErrHandler
If Not Intersect(Range("B3:D14"), Target) Is Nothing Then
Worksheets(1).Unprotect
For Each rng In Intersect(Range("B3:D14"), Target)
R = Cells(rng.Row, 5)
G = Cells(rng.Row, 6)
B = Cells(rng.Row, 7)
Swatch = rng.Row - 2
R = WorksheetFunction.Max(0, (WorksheetFunction.Min(255, R))) ' ...avoid runtime error when changing displayed color
G = WorksheetFunction.Max(0, (WorksheetFunction.Min(255, G)))
B = WorksheetFunction.Max(0, (WorksheetFunction.Min(255, B)))
With Worksheets(1).ChartObjects(6).Chart.SeriesCollection(1)
.Points(Swatch).MarkerBackgroundColor = RGB(R, G, B)
.DataLabels(Swatch).Font.Color = RGB(R, G, B)
End With
Next rng
End If
ExitHandler:
Worksheets(1).Protect
Exit Sub
ErrHandler:
MsgBox Err.Description, vbExclamation
Resume ExitHandler
End Sub
See
https://www.dropbox.com/s/nylonrp0y86lq1c/FAA%20palette%20designer%20Beta%2002.xlsm?dl=1
Regards, Hans Vogelaar (http://www.eileenslounge.com)