How to put header in a report?

Question

hi,
I am working on a  cash flow report. In this, in the selection screen, I am giving selection fields as Profit Center and Period ( MM/YYYY) format.
now, while displaying the report I want that the period which has been selected in the selection field, should get displayed column wise.
For eg.
If the period selected is: June'2005 To August'2005.
then, it should get displayed as:
                June'2005   Jul'2005   August'2005.
So, is there any function module which can be used for displaying it in the report in the above mentioned manner.
IF you want any other detail about the report. Just let me know.
Regards,
Ravi

Answer 1

You can do this with a little creativity and a dynamic internal table.  Here is a sample program which uses a select-option for date instead of month/year. But it can be done the same with month/year.  Also the formatting of the headings and data will need to be manipulated a little.
report zrich_0003
       no standard page heading.
type-pools: slis.
field-symbols: <dyn_table> type standard table,
               <dyn_wa>,
               <dyn_field>.
data: begin of it_datum occurs 0,
      datum type sy-datum,
      end of it_datum.
data: fieldlist type table of rstrucinfo with header line.
selection-screen begin of block b1 with frame title text-001.
select-options: s_datum for sy-datum.
selection-screen end of block b1.
initialization.
  s_datum-sign = 'I'.
  s_datum-option = 'BT'.
  s_datum-low = sy-datum.
  s_datum-high = sy-datum + 7.
  append s_datum.
start-of-selection.
  perform build_dyn_itab.
  perform build_report.
* Write headings
  loop at it_datum.
    write: it_datum-datum.
  endloop.
* Write out data from table.
  loop at <dyn_table> into <dyn_wa>.
    do.
      assign component  sy-index  of structure <dyn_wa> to <dyn_field>.
      if sy-subrc <> 0.
        exit.
      endif.
      if sy-index = 1.
        write:/ <dyn_field>.
      else.
        write: <dyn_field>.
      endif.
    enddo.
  endloop.
*  Build_dyn_itab
form build_dyn_itab.
  data: index(3) type c.
  data:   it_fldcat type lvc_t_fcat,
          wa_fldcat type lvc_s_fcat.
  data: new_table type ref to data,
        new_line  type ref to data.
  do.
    clear wa_fldcat.
    wa_fldcat-datatype = 'QUAN'.
    wa_fldcat-intlen   = '10'.
    wa_fldcat-fieldname = s_datum-low.
    append wa_fldcat to it_fldcat.
    it_datum-datum = s_datum-low.
    append it_datum.
    if s_datum-low = s_datum-high.
      exit.
    endif.
    s_datum-low = s_datum-low + 1.
  enddo.
* Create dynamic internal table and assign to FS
  call method cl_alv_table_create=>create_dynamic_table
    exporting
      it_fieldcatalog = it_fldcat
    importing
      ep_table        = new_table.
  assign new_table->* to <dyn_table>.
* Create dynamic work area and assign to FS
  create data new_line like line of <dyn_table>.
  assign new_line->* to <dyn_wa>.
endform.                    "build_dyn_itab
*      Form  build_report
form build_report.
  data: fieldname(20) type c.
  data: fieldvalue type i value '10'.
  data: index(3) type c.
  field-symbols: <fs1>.
* Put data into the tabl
  loop at it_datum.
    do.
      assign component  sy-index  of structure <dyn_wa> to <fs1>.
      if sy-subrc <> 0.
        exit.
      endif.
      <fs1> =  fieldvalue.
      fieldvalue = fieldvalue + 10.
    enddo.
* Append to the dynamic internal table
    append <dyn_wa> to <dyn_table>.
  endloop.
endform.                    "build_report
REgards,
Rich Heilman