How to restrict running of report in foreground

Question

My requirement is that, the user should not be allowed to run the report in foreground. Since there is a high possibility for the report  to go to time-out.. I want to force the user to run it in background only.. How can we do that ? IS it Basis related or .. can it be done in abap ?
Thanking you..
Shankar

Answer 1

Hi Shankara,
Here is what is happening with your logic.
1. User is running the program and got to the selection screen.
2. User enters the selection values and then presses execute.
3. User gets the diaolog box asking him whether the program should be run in the background.
4. User says yes and you are doing the submit of your program.
The problem lies in the step 4 where you are submitting your program.
Remember, when you submit a program, you are supposed to have passed the selection screen data in one of the standard ways of passing the data which is either creating a variant and passing the variant to the job, or use SPA/GPA parameters if relevant or any other method.
Since you are calling your program again within the same program, but without passing the selection screen values, your program is failing. Here is a sample program to achieve what you are trying to achieve.
REPORT ztest.
PARAMETERS: p_vbeln LIKE vbak-vbeln,
            p_bkrun NO-DISPLAY.
DATA: ls_vbak LIKE vbak.
DATA: v_answer,
      v_jobcount LIKE tbtcjob-jobcount.
  IF p_bkrun IS INITIAL.
*-- not background processing
    CALL FUNCTION 'POPUP_TO_CONFIRM_STEP'
         EXPORTING
              textline1      = 'This may time out.'
              textline2      = 'Do you want to run in background?'
              titel          = 'Warning!!!'
              cancel_display = space
         IMPORTING
              answer         = v_answer.
    IF v_answer = 'J'.
*-- run in the background
      CALL FUNCTION 'JOB_OPEN'
           EXPORTING
                jobname          = 'ZTEST'
           IMPORTING
                jobcount         = v_jobcount
           EXCEPTIONS
                cant_create_job  = 1
                invalid_job_data = 2
                jobname_missing  = 3
                OTHERS           = 4.
      IF sy-subrc <> 0.
        MESSAGE ID sy-msgid TYPE 'E' NUMBER sy-msgno
                WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
        EXIT.
      ENDIF.
*-- submit the program in the background
      SUBMIT ztest
        WITH p_bkrun = 'X'
        WITH p_vbeln = p_vbeln
        USER sy-uname
        VIA JOB 'ZTEST' NUMBER v_jobcount AND RETURN.
*-- close the job
      CALL FUNCTION 'JOB_CLOSE'
           EXPORTING
                jobcount             = v_jobcount
                jobname              = 'ZTEST'
                strtimmed            = 'X'
           EXCEPTIONS
                cant_start_immediate = 1
                invalid_startdate    = 2
                jobname_missing      = 3
                job_close_failed     = 4
                job_nosteps          = 5
                job_notex            = 6
                lock_failed          = 7
                OTHERS               = 8.
      IF sy-subrc <> 0.
        MESSAGE ID sy-msgid TYPE 'W' NUMBER sy-msgno
                WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
      ENDIF.
      EXIT.
    ELSE.
      CLEAR v_answer.
    ENDIF.
  ENDIF.
  CHECK v_answer IS INITIAL.
  SELECT SINGLE * FROM vbak
                  INTO ls_vbak
                 WHERE vbeln = p_vbeln.
  IF sy-subrc <> 0.
    WRITE:/ 'Invalid Order Id.'.
  ENDIF.
END-OF-SELECTION.
  CHECK v_answer IS INITIAL.
  IF p_bkrun IS INITIAL.
    WRITE:/ 'Here is the result running the program in foreground.'.
  ELSE.
    WRITE:/ 'Here is the result running the program in background.'.
  ENDIF.
  WRITE:/ ls_vbak-vbeln,
          ls_vbak-vkorg.
Let me know if you have any questions.
Srinivas