How to Trigger a Job from se38 Report

Question

Hi,
I need to trigger a job from an se38 report program.
Currently the code I'm using is:
  SUBMIT YARTZ_SPOOL
         USER SY-UNAME
         VIA JOB 'YARTZ_JOB2'
         NUMBER 1
         TO SAP-SPOOL
         SPOOL PARAMETERS l_print_parms
         WITHOUT SPOOL DYNPRO
         AND RETURN.
But the SY_SUBRC return I get is 8 which stands for 'Error In job Scheduling'
Is the method used correct?
Or am i going wrong in scheduling the job? As far as Job scheduling goes, I used the Date/Time schedule and scheduled it at a time 20 minutes later.
Thanks.

Answer 1

Hi,
use the code
  IF p_bjob = 'X'.
    CONCATENATE sy-cprog sy-datum sy-uzeit
                INTO jobname SEPARATED BY '_'.
    CALL FUNCTION 'JOB_OPEN'
      EXPORTING
        jobname          = jobname
      IMPORTING
        jobcount         = jobcount
      EXCEPTIONS
        cant_create_job  = 1
        invalid_job_data = 2
        jobname_missing  = 3
        OTHERS           = 4.
    CALL FUNCTION 'GET_PRINT_PARAMETERS'
      IMPORTING
        out_archive_parameters = arc_params
        out_parameters         = print_params
        valid                  = valid
      EXCEPTIONS
        archive_info_not_found = 1
        invalid_print_params   = 2
        invalid_archive_params = 3
        OTHERS                 = 4.
    IF valid = chk.
      SUBMIT YARTZ_SPOOL
                      WITH <selection-screen parameters if any>
                      AND RETURN
                      USER               sy-uname
                      VIA JOB            jobname
                      NUMBER             jobcount
                      TO SAP-SPOOL
                      SPOOL PARAMETERS   print_params
                      ARCHIVE PARAMETERS arc_params
                      WITHOUT SPOOL DYNPRO.
      CALL FUNCTION 'JOB_CLOSE'
        EXPORTING
          jobcount             = jobcount
          jobname              = jobname
          strtimmed            = 'X'
        EXCEPTIONS
          cant_start_immediate = 1
          invalid_startdate    = 2
          jobname_missing      = 3
          job_close_failed     = 4
          job_nosteps          = 5
          job_notex            = 6
          lock_failed          = 7
          invalid_target       = 8
          OTHERS               = 9.
      IF sy-subrc <> 0.
       MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
      ELSE.
        MESSAGE i029 WITH jobname.
      ENDIF.
    ELSE.
      MESSAGE s000 WITH text-003.
      STOP.
    ENDIF.
  ENDIF.
reward points if useful
regards,
Anji