How to use linktoaction in table

Question

Hi,
How can I use linktoaction in a table for each row where I need to give a remove option with linktoaction each row by clicking the linktoaction  that row should delete from table.
Thanks in advance
Regards
Raj

Answer 1

Dear Raj,
After creating your table UI, right click and select Create Binding.
After Selecting your node and attributes in the pop- up, select the Cell Editor of the Table Column as LinkToAction.
Then go to  this Table Cell and provide the action for the LinkToAction UI say OnActionRemove.
Now,  double click on OnActionRemove and write the following code.
* Local Data
  DATA: lfd_clicked_index TYPE i.
  DATA: lfd_xfeld         TYPE xfeld.
* Get the clicked index
  lfd_clicked_index = context_element->get_index( ).
* Read the row on which the LinkToAction to Remove clicked
  DATA lo_nd_your_node TYPE REF TO if_wd_context_node.
  DATA lo_el_your_node TYPE REF TO if_wd_context_element.
* navigate from <CONTEXT> to <YOUR_NODE> via lead selection
  lo_nd_your_node = wd_context->get_child_node( name = wd_this->wdctx_your_node ).
* alternative access  via index
  lo_el_your_node = lo_nd_your_node->get_element( index = lfd_clicked_index ).
* Remove the row.
  lfd_xfeld = lo_nd_your_node->remove_element( element = lo_el_your_node ).
CHECK lfd_xfeld = abap_true.
* Give successful removal message
* get message manager
  DATA lo_api_controller  TYPE REF TO if_wd_controller.
  DATA lo_message_manager TYPE REF TO if_wd_message_manager.
  lo_api_controller ?= wd_this->wd_get_api( ).
  CALL METHOD lo_api_controller->get_message_manager
    RECEIVING
      message_manager = lo_message_manager.
* Report message
  CALL METHOD lo_message_manager->report_success
    EXPORTING
      message_text = 'row removed successfully.'.
Please note that you have to provide
CONTEXT_ELEMENT     Importing          IF_WD_CONTEXT_ELEMENT,  as action parameter.
Hope it helps!.
Warm regards,
Upendra Agrawal