I want to stop loop through push button forms 10g

Question

I want to stop looping through push button forms 10g it is like (SwingWorker() in java) (DoEvent() in .net)
The problem in forms 10g that when you start looping the form will freeze and you can't push any button on form, I found solution for that in form 6i through package d2kwutil **WIN_API_UTILITY.InterruptCheck(hButton)**
But in 10g I can't find solution, Please help>>>>>
declare
     hButton          PLS_INTEGER;
begin
:interruptcheck.counter := 0;
hButton := get_item_property('INTERRUPTCHECK.PB_OFF',WINDOW_HANDLE);
go_item('interruptcheck.loopcount');
set_item_property('INTERRUPTCHECK.PB_OFF',ENABLED,PROPERTY_TRUE);
set_item_property('INTERRUPTCHECK.PB',ENABLED,PROPERTY_FALSE);
set_application_property(CURSOR_STYLE,'HELP');
set_application_property(CURSOR_STYLE,'<d2kwut60>WAIT');
for i in 1..:interruptcheck.loopcount LOOP
     if WIN_API_UTILITY.InterruptCheck(hButton) then
          exit;
     end if;
     :interruptcheck.counter := i;
     synchronize;
end loop;
set_item_property('INTERRUPTCHECK.PB_OFF',ENABLED,PROPERTY_FALSE);
set_item_property('INTERRUPTCHECK.PB',ENABLED,PROPERTY_TRUE);
set_application_property(CURSOR_STYLE,'DEFAULT');
end;
Edited by: wael amar on May 1, 2010 11:03 PM

Answer 1

Ok, here's a working testcase.
The idea is taken from an article from an oracle magazine (i don't have it at hand, , so i tried to rebuild it by "memory". As far as i remember the original was from the german doag-magazine and was written by Gerd Volberg).
Procedure to do the looping:
PROCEDURE PR_DO_THE_LOOP IS
  nNumberInOneStep NUMBER:=2;
  tm               TIMER;
BEGIN
     DEFAULT_VALUE(0, 'GLOBAL.INDEX');
  IF :GLOBAL.INDEX=0 THEN
       -- Didn't run yet, determine the max count
       :GLOBAL.MAX:=10000;
  END IF;
  LOOP
       -- Do the looping stuff
       -- Decrease counter
       nNumberInOneStep:=nNumberInOneStep-1;
       -- Increase globale counter
       :GLOBAL.INDEX:=:GLOBAL.INDEX+1;
       -- Exit conditions
       EXIT WHEN nNumberInOneStep=0;
       EXIT WHEN TO_NUMBER(:GLOBAL.INDEX)>=TO_NUMBER(:GLOBAL.MAX);
  END LOOP;
  -- reset index at end
  IF TO_NUMBER(:GLOBAL.INDEX)>=TO_NUMBER(:GLOBAL.MAX) THEN
       :GLOBAL.INDEX:=0;
  ELSE
       -- start timer for next iteration
       tm:=CREATE_TIMER('TM', 10, NO_REPEAT);
  END IF;
END;The WHEN-TIMER-EXPIRED-trigger
IF :GLOBAL.INTERRUPTED='Y' THEN
     MESSAGE('Interrupted at index ' || :GLOBAL.INDEX);
ELSE
     PR_DO_THE_LOOP;
END IF;The WHEN-BUTTOn-PRESSED-trigger on the interrupt-button
:GLOBAL.INTERRUPTED:='Y';The WHEN-BUTTOn-PRESSED-trigger on the "start"-button
:GLOBAL.INTERRUPTED:='N';
PR_DO_THE_LOOP;