If statement in a cursor

Question

Hi
I am trying to have a if statement inside a cursor clause. But it gives me error saying that "PLS-00103: Encountered the symbol "IF" when expecting one of the following: ( select <a SQL statement>". I know this is not the right syntax so is there any way that I can specify the table that the cursor should get its information from based on a if clause.
The typeID field tells me which table to go to to get the information from. So if typeId=1 then go to table1 if it is type=2 then go to table2 etc.....
CREATE OR REPLACE PROCEDURE FILLDATA(
     typeID IN NUMBER
) IS
data varchar2(16);
dataresult varchar2(16);
cursor c1 is
        IF typeID=1 then
     select value from TableName#1
        ELSE
     select value from TableName#2
        END IF;
     where id='1';
begin
     open c1;
     dataresult:='';
      loop
      fetch c1 into dataresult;
      EXIT WHEN c1%NOTFOUND;
         data:=concat(to_char(data), to_char(dataresult));
      end loop;
     close c1;
end
Your help will be really appreciated. Thanks a lot.
Message was edited by:
user561977
Message was edited by:
user561977
Message was edited by:
user561977

Answer 1

Or I guess:
DECLARE
    cur SYS_REFCURSOR;
BEGIN
    CASE ROUND(DBMS_RANDOM.VALUE(1,2))
        WHEN 1 THEN OPEN cur FOR SELECT id FROM t1;
        WHEN 2 THEN OPEN cur FOR SELECT id FROM t2;
    END CASE;
    CLOSE cur;
END;Also I can't think of a practical use for this here, but you can assign one ref cursor to another:
DECLARE
    c1 SYS_REFCURSOR;
    c2 SYS_REFCURSOR;
    c_generic SYS_REFCURSOR;
BEGIN
    CASE ROUND(DBMS_RANDOM.VALUE(1,2))
        WHEN 1 THEN
            DBMS_OUTPUT.PUT_LINE('Picked value: 1');
            OPEN c1 FOR SELECT id FROM t1;
            c_generic := c1;
        WHEN 2 THEN
            DBMS_OUTPUT.PUT_LINE('Picked value: 2');
            OPEN c2 FOR SELECT id FROM t2;
            c_generic := c2;
    END CASE;
    CLOSE c_generic;
    IF c1%ISOPEN THEN
        DBMS_OUTPUT.PUT_LINE('c1 is open.');
        CLOSE c1;
    ELSIF c2%ISOPEN THEN
        DBMS_OUTPUT.PUT_LINE('c2 is open.');
        CLOSE c2;
    ELSE
        DBMS_OUTPUT.PUT_LINE('It appears that neither c1 nor c2 is open.');
    END IF;
END;
Picked value: 2
It appears that neither c1 nor c2 is open.
PL/SQL procedure successfully completed.Message was edited by:
William Robertson