Implementing Note 487917 ,,, error - to create object

Question

Hi,
I am implementing SAP note 487917 through SNOTE.
But I am getting an error saying:
Create an empty object METH ZZ_NOTE_487917 with the corresponding object editor.
Version: SRM-5.0
Can someone guide me to create an object with type METH?
I have no Idea on OO-ABAP.
Thanks,
Ashwin.

Answer 1

Hi Ashwin,
You need to create a Z/custom implementation for the BADI "BBP_CATALOG_TRANSFER".You cannot apply this note directly thorugh SNOTE.
Follow these steps;
-->Goto trascn SE19.
-->Create a Z implementation for the BADI BBP_CATALOG_TRANSFER ,say zBBP_CATALOG_TRANSFER.
-->Then give some description and under methods tab,click on the method ENRICH_ITEM_DATA.
-->In this method,in the editor,write the code which is given in the attached instructions in the note
i.e.
This implementation is writing all the fields that are filled
in the OCI-Interface to the application log BCT1. Furhtermore
it is also storing the error messages from ENRICH_ITEM_DATA to
the same log. The log can be view with transaction SLG1.
******** DATA DECLARATION **************************************
Work area for catalog_content
  DATA: ITAB_WA        TYPE bbp_ws_oci_item_s.
Data of the aplication log
  DATA: L_S_LOG        TYPE BAL_S_LOG. "Header of application log
  DATA: L_S_TEXT(200)  TYPE C. "Message lines
  DATA: L_S_HANDLE     TYPE BALLOGHNDL. "Log Handle.
  DATA: L_T_HANDLE_TAB TYPE BAL_T_LOGH. "Handle tab for BAL_DB_SAVE
Data for OCI-Fields
  DATA: OCI_FIELDS     TYPE DDFIELDS. "all OCI-fields
  DATA: OCI_FIELDS_WA  TYPE DFIES. "work area for OCI-fields
  DATA: HELP_FIELD(30) TYPE C. "dynamic field for loop at OCI-fields
  DATA: DISP_FIELD(30) TYPE C.
  DATA: H2(40)         TYPE C. "conversion to type C
  FIELD-SYMBOLS: <F1>  TYPE ANY.
Data for OCI-Error-Tab
  DATA: CATALOG_CONTENT_ERRORS_WA TYPE BBP_OCI_ERRORS.
******** END OF DATA DECLARATION *********************************
Read all the fields of the OCI-Interface.
  CALL FUNCTION 'GET_FIELDTAB'
       EXPORTING
            tabname  = 'BBP_WS_OCI_ITEM_S'
       TABLES
            fieldtab = oci_fields.
create a log
  L_S_LOG-EXTNUMBER = 'CATALOG_DOWNLOAD'.
  L_S_LOG-ALUSER    = SY-UNAME.
  L_S_LOG-ALPROG    = SY-REPID.
  L_S_LOG-OBJECT    = 'BCT1'.
  CALL FUNCTION 'BAL_LOG_CREATE'
       EXPORTING
            I_S_LOG      = L_S_LOG
       IMPORTING
            E_LOG_HANDLE = L_S_HANDLE
       EXCEPTIONS
            OTHERS       = 1.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
fill the data for the Application Log
  CLEAR ITAB_WA.
  LOOP AT CATALOG_CONTENT INTO ITAB_WA.
loop at all oci-fields and add nonempty fields to the appl. log
    LOOP AT OCI_FIELDS INTO OCI_FIELDS_WA.
     CONCATENATE 'ITAB_WA-' OCI_FIELDS_WA-FIELDNAME INTO HELP_FIELD.
     ASSIGN (HELP_FIELD) TO <F1>.
     IF <F1> IS INITIAL.
only write the fields that are not initial
     ELSE.
      H2 = <F1>.    "conversion to type C
      CONCATENATE 'NEW_ITEM-' OCI_FIELDS_WA-FIELDNAME INTO DISP_FIELD.
      CONCATENATE DISP_FIELD '=' H2 INTO L_S_TEXT SEPARATED BY SPACE.
add this line to the application log
      CALL FUNCTION 'BAL_LOG_MSG_ADD_FREE_TEXT'
           EXPORTING
                I_LOG_HANDLE     = L_S_HANDLE
                I_MSGTY          = 'I'
                I_TEXT           = L_S_TEXT
           EXCEPTIONS
                LOG_NOT_FOUND    = 1
                MSG_INCONSISTENT = 2
                LOG_IS_FULL      = 3
                OTHERS           = 4.
      IF SY-SUBRC <> 0.
        MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      ENDIF.
     ENDIF.
    ENDLOOP.
check if there are errors for this item in CATALOG_CONTENT_ERRORS
    LOOP AT CATALOG_CONTENT_ERRORS INTO CATALOG_CONTENT_ERRORS_WA
            WHERE LINE = ITAB_WA-LINE.
       CONCATENATE
          CATALOG_CONTENT_ERRORS_WA-LINE
          CATALOG_CONTENT_ERRORS_WA-TYPE
          CATALOG_CONTENT_ERRORS_WA-CODE
          CATALOG_CONTENT_ERRORS_WA-MESSAGE
          CATALOG_CONTENT_ERRORS_WA-MESSAGE_V1
          CATALOG_CONTENT_ERRORS_WA-MESSAGE_V2
          CATALOG_CONTENT_ERRORS_WA-MESSAGE_V3
          CATALOG_CONTENT_ERRORS_WA-MESSAGE_V4
      INTO L_S_TEXT SEPARATED BY SPACE.
add this line to the application log
      CALL FUNCTION 'BAL_LOG_MSG_ADD_FREE_TEXT'
           EXPORTING
                I_LOG_HANDLE     = L_S_HANDLE
                I_MSGTY          = CATALOG_CONTENT_ERRORS_WA-TYPE
                I_TEXT           = L_S_TEXT
           EXCEPTIONS
                LOG_NOT_FOUND    = 1
                MSG_INCONSISTENT = 2
                LOG_IS_FULL      = 3
                OTHERS           = 4.
      IF SY-SUBRC <> 0.
         MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      ENDIF.
    ENDLOOP.
  ENDLOOP.
Save this log to the data base (Log-Object = BCT1)
  CLEAR L_T_HANDLE_TAB.
  APPEND L_S_HANDLE TO L_T_HANDLE_TAB.
  CALL FUNCTION 'BAL_DB_SAVE'
       EXPORTING
            I_T_LOG_HANDLE   = L_T_HANDLE_TAB
       EXCEPTIONS
            LOG_NOT_FOUND    = 1
            SAVE_NOT_ALLOWED = 2
            NUMBERING_ERROR  = 3
            OTHERS           = 4.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
-->After that save and  activate your implementation.
Pls let me know if you need any further help.
BR,
Disha.
Do reward full points for useful answers.