Insert Document name in Pages

Question

Is there a way to insert the document name as automatic text at the bottom of the first page in Pages? This was a simple "automatic text" script that Word has had for years. All of our documents are saved with names relating to what the document is and where it gets filed. Our paper filing/folder structure is pretty much identical to the folder structure of our file server. It is very convenient to have the name of the document printed at the bottom of the first page so that when it comes time to filing our hard copies, one knows exactly where to file it.
There must be a way to script this. Any help would be much appreciated. Thanks.

Answer 1

Automator isn't really the best solution to this. It's possible to do it with AppleScript, and granted, anything you can do in AppleScript can be put into an Automator workflow.
There seems to be three possible ways to mark the bottom of the document:
1) Insert carriage returns to position the very last paragraph (the name of the document) at the bottom. Drawback: if your document takes up all of the final page, then you'd have to create a blank page to accomodate the name. Also, determining the exact number of returns to insert isn't very easy.
2) Put the name in the footer. Drawback: footers appear on every page, not just the last. You could create a separate trailing section, but that has a blank-page issue similar to #1.
3) Create a text box at the bottom of the last page. Here's a little script that will do that.
As for triggering the script, the simplest way is probably to use the AppleScript utility to enable the system AppleScript menu, and put the script in the Pages scripts folder. Then it'll be available whenever you're running Pages.
<PRE>
-- Assumptions:
-- - units are inches
-- - pages are 8.5 x 11
property pageHeight : 11.0
property pageWidth : 8.5
tell document 1 of application "Pages"
set bottomMargin to bottom margin
set leftMargin to left margin
set theBottom to pageHeight - bottomMargin
-- Apparently, the new text box will be created on the page which is visible
reveal page (page count)
if path exists then
-- if you prefer Unix-style pathnames, then use
-- set docName to path
set docName to path as POSIX file as text
else
-- Might want to prompt user to save here.
-- otherwise, fall back on the document name, typically "untitled"
set docName to name
end if
make text box with properties {object text:docName ¬
, vertical position:theBottom, horizontal position:leftMargin ¬
, height:bottomMargin, width:(pageWidth - left margin - right margin)}
tell result
-- Some optional formatting
set alignment of object text to center
set italic of object text to true
set font size of object text to 18
set font name of object text to "Palatino"
end tell
end tell
</PRE>
Titanium PowerBook   Mac OS X (10.4.4)