IPhoto Pictures Stuck in Aperture

Question

I keep getting a message when trying to delete some photos in iPhoto:
This photo is in an Aperture stack and cannot be put into the iPhoto Trash. Use Aperture to delete this photo.
I have removed all the photos from Aperture, including emptying the Aperture trash.  So, not sure why I'm getting this message if there aren't any photos in the Aperture library???  Any ideas would be great, thank you.

Answer 1

1. make a backup of your iPhoto library folder or the 'Originals' folder within.
2. paste this script into Script Editor and save it as an Application.
3. in the Finder, drop the 'Originals' folder from within the iPhoto library onto the new application; what we call a Droplet. the Finder will replace all aliases within the folder and nested folders with their original image files.
the script:
-- begin
to open theFolders
   repeat with i from 1 to theFolders's length
      copy theFolders's item i to theFolder
      if (theFolder as string) ends with ":" then
         replaceWithOriginal(theFolder)
      end if
   end repeat
   return
end open
to replaceWithOriginal(theFolder)
   tell application "Finder"
      set containedItems to every alias file of theFolder
      repeat with i from 1 to containedItems's length
         copy containedItems's item i to theAlias
         try
            copy theAlias's original item to theOriginal
            duplicate theOriginal to theAlias's container with replacing
         on error number -1728 -- orphaned alias
            delete theAlias
         end try
      end repeat
      set containedFolders to every folder of theFolder
      repeat with i from 1 to containedFolders's length
         replaceWithOriginal(containedFolders's item i) of me
      end repeat
   end tell
end replaceWithOriginal
-- end