Join of cursor with table

Question

Hi experts,
Oracle Version: 11GR2
I get dataset in the ref cursor as an out parameter from a procedure. Now, I have to derive column "NAME" from table "TEST" using ID as a join key between cursor and a table.
How can we do this in oracle?
Thanks

Answer 1

You cant join a cursor to a table. cursor is a SQL work area where instruction to execute a SQL is processed.
I could think of three approaches
1. The best way is to include the table "TEST" in the original SQL that builds the cursor.
2. If that is not possible then you need to fetch them (may be) into a SQL collection type and then join the table "TEST" with the collection type.
3. Or you may have to loop thorough the cursor and then for each row fetched you would have to join with the table "TEST"
Lets say this is your procedure
create or replace procedure getdept
  p_out_rc out sys_refcursor
as
begin
  open p_out_rc for
  select deptno
    from dept;
end;
Example for 2nd approach
Create a SQL Nested Table.
create or replace type deptno_tbl as table of number(10)
And you write a PL/SQL code like this. Code in red is the one to consider.
SQL> declare
  2    l_deptno deptno_tbl;
  3    l_rc     sys_refcursor;
  4  begin
  5    getdept(l_rc);
  6    fetch l_rc bulk collect into l_deptno;
  7
  8    for i in (
  9               select ename
10                 from emp e
11                 join table(l_deptno) t
12                   on e.deptno = t.column_value
13             )
14    loop
15      dbms_output.put_line(i.ename);
16    end loop;
17  end;
18  /
KING
CLARK
ADAMS
SCOTT
JONES
SMITH
TURNER
BLAKE
MARTIN
WARD
ALLEN
Example for 3rd approach.
SQL> declare
  2    l_rc     sys_refcursor;
  3    l_deptno number(10);
  4  begin
  5    getdept(l_rc);
  6    loop
  7      fetch l_rc into l_deptno;
  8      exit when l_rc%notfound;
  9      for i in (
10                 select ename
11                   from emp e
12                  where e.deptno = l_deptno
13               )
14      loop
15        dbms_output.put_line(i.ename);
16      end loop;
17    end loop;
18  end;
19  /
CLARK
KING
SMITH
JONES
SCOTT
ADAMS
ALLEN
WARD
MARTIN
BLAKE
TURNER
Finally I would again like to highlight that first approach is by far the best approach. The second and third approach has there own performance downside.