KIMYONG : API ( FND_SUBMIT, FND_REQUEST) Sample Code 소개

Question

Purpose
Extension 개발자들이 간혹 요청하는 Standard API (FND_SUBMIT, FND_REQUEST)의 sample code입니다.
Configuring the Script
FND_SUBMIT test procedure and sample code
Creates a procedure called fnd_submit_test that can be registered and run as a concurrent program.
This procedure will use the FND_SUBMIT API to submit a request set. (Function Security Reports - This request set should be seeded, if it is not available the values in the script may need to be changed.) The procedure will then place itself in a Paused status until the request set completes.
Running the Script
1. Install this procedure in the APPS schema.
2. Register the procedure as a concurrent program
Caution
This script is provided for educational purposes only and not supported by Oracle Support Services. It has been tested internally, however, and works as documented. We do not guarantee that it will work for you, so be sure to test it in your environment before relying on it.
Proofread this script before using it! Due to the differences in the way text editors, e-mail packages and operating systems handle text formatting (spaces, tabs and carriage returns), this script may not be in an executable state when you first receive it. Check over the script to ensure that errors of this type are corrected.
Script
REM +==========================================================================
REM | Concurrent Processing Sample Code
REM |
REM | FILE:
REM | fnd_submit_test.pls
REM |
REM | REVISION:
REM | $Id$
REM |
REM | DESCRIPTION:
REM | FND_SUBMIT test procedure and sample code
REM | Creates a procedure called fnd_submit_test that can be registered
REM | and run as a concurrent program.
REM | This procedure will use the FND_SUBMIT API to submit a request set.
REM | (Function Security Reports - This request set should be seeded, if
REM | it is not available the values in the script may need to be changed.)
REM | The procedure will then place itself in a Paused status until the
REM | request set completes.
REM |
REM | INSTRUCTIONS:
REM |
REM | 1. Install this procedure in the APPS schema.
REM |
REM | 2. Register the procedure as a concurrent program
REM |
REM |
REM +==========================================================================
whenever sqlerror exit failure rollback;
create or replace procedure fnd_submit_test (errbuf out varchar2,
retcode out varchar2) as
success boolean;
req_id number;
req_data varchar2(10);
srs_failed exception;
submitprog_failed exception;
submitset_failed exception;
begin
-- Use FND_FILE to output messages at each stage
fnd_file.put_line(fnd_file.log, 'Starting test...');
-- Read fnd_conc_global.request_data, if available then we have been
-- reawakened after the request set has completed.
-- If so, exit.
req_data := fnd_conc_global.request_data;
if (req_data is not null) then
errbuf := 'Done!';
retcode := 0 ;
return;
end if;
-- Step 1 - call set_request_set
fnd_file.put_line(fnd_file.log, 'Calling set_request_set...');
success := fnd_submit.set_request_set('FND', 'FNDRSSUB43');
if ( not success ) then
raise srs_failed;
end if;
fnd_file.put_line(fnd_file.log, 'Calling submit program first time...');
-- Step 2 - call submit program for each program in the set
success := fnd_submit.submit_program('FND','FNDMNFUN', 'STAGE10', 'System Administrator', chr(0));
if ( not success ) then
raise submitprog_failed;
end if;
fnd_file.put_line(fnd_file.log, 'Calling submit program second time...');
success := fnd_submit.submit_program('FND','FNDMNMNU', 'STAGE10', 'System Administrator', chr(0));
if ( not success ) then
raise submitprog_failed;
end if;
fnd_file.put_line(fnd_file.log, 'Calling submit program third time...');
success := fnd_submit.submit_program('FND','FNDMNNAV', 'STAGE10', 'System Administrator', chr(0));
if ( not success ) then
raise submitprog_failed;
end if;
-- Step 3 - call submit_set
fnd_file.put_line(fnd_file.log, 'Calling submit_set...');
req_id := fnd_submit.submit_set(null,true);
if (req_id = 0 ) then
raise submitset_failed;
end if;
fnd_file.put_line(fnd_file.log, 'Finished.');
-- Set conc_status to PAUSED, set request_data to 1 and exit
fnd_conc_global.set_req_globals(conc_status => 'PAUSED', request_data => '1') ;
errbuf := 'Request set submitted. id = ' || req_id;
retcode := 0;
exception
when srs_failed then
errbuf := 'Call to set_request_set failed: ' || fnd_message.get;
retcode := 2;
fnd_file.put_line(fnd_file.log, errbuf);
when submitprog_failed then
errbuf := 'Call to submit_program failed: ' || fnd_message.get;
retcode := 2;
fnd_file.put_line(fnd_file.log, errbuf);
when submitset_failed then
errbuf := 'Call to submit_set failed: ' || fnd_message.get;
retcode := 2;
fnd_file.put_line(fnd_file.log, errbuf);
when others then
errbuf := 'Request set submission failed - unknown error: ' || sqlerrm;
retcode := 2;
fnd_file.put_line(fnd_file.log, errbuf);
end;
rem ===================================================================
commit;
exit;
Reference
자세한 사항은 Note 221542.1 를 참고하세요.

Answer 1

Not sure about that particular option, but in general you pass in pairs - an example from code I didn't write but maintain (so if this is the worst possible way, I apologize)
proj_req_id6 := FND_REQUEST.SUBMIT_REQUEST('SQLGL', 'XXXX_GLGENLED_PDF',
                          'XXXX General Ledger',
                          '',dummy_default,
                          'P_SET_OF_BOOKS_ID='||v_rep_cmp.set_of_books_id,'P_CHART_OF_ACCOUNTS_ID=101',
                          'P_KIND=L','P_CURRENCY_CODE='||v_rep_cmp.currency_code,
                          'P_ACTUAL_FLAG=A','P_BUD_ENC_TYPE_ID=100',
                          'P_START_PERIOD='||'&1','P_END_PERIOD='||'&1',
                          'P_MIN_FLEX='||v_min_flex||'.'||v_emp_cost_center.COST_CENTER||'.00000.000.000.000.00',
                          'P_MAX_FLEX='||v_max_flex||'.'||v_emp_cost_center.COST_CENTER||'.99999.999.999.ZZZ.99',
                          'P_PAGE_SIZE=180',chr(0),'',
                          '','','','','','','','','','');You see where I have option pairs - for example
'P_ACTUAL_FLAG=A'Tells my program that the value for parameter P_ACTUAL_FLAG is A
This example is from a SQL*Plus script, hence the &1 for the value substitutions.
Hope that helps