Link between Financial Statement Item and Break-Down-Category

Question

Dear all,
we try to create an own data entry functionality in SAPNetweaver for our BCS Data.
Therefore we need to implement a coding vor a validation (IP-coding). Do you know in which table we get the link between the financial statement item and the break-down category?
The customizing phath is
TA UCWB > Master Data > Items > Item (select item) > Field Breakdown Category (field name: ITGRP).
We need the tecnical link (table/structure) so that we can create a validation based on the financial statement and the breakdown category).
Thanks!
XmchX

Answer 1

The tables themselves are generated objects that are structured based on how you've defined your master data (custom attributes, etc). 
You can probably find them through table UGMD2011 and entering the fieldname of your FS Item (I think the delivered item is /1FB/CS_ITEM).
The following snippet is from a function module I wrote to check movement type restrictions (min/max selection set) might be useful.  I've previously created a custom task for posting custom documents (that could not be defined with standard reclassifications or IU eliminations). 
I've never worked with the portal, but presumably you can create an RFC interface and replicate the selections which normally come from the cons monitor (Cons Area, GC, FYV, Period, Year, Cons Chart, + and additional fields fixed in the cons area) on a portal page and inherit them that way.  I actually thought about creating an Excel workbook that would send postings directly into BCS...just never got the time, and it was never a "requirement" as the volume of manually entries has been pretty low (or, at least always planned to be low)
  CONSTANTS:
  c_area            TYPE uc_area      VALUE 'US',              " Consolidation Area
  c_chart           type uc_value     value 'US',              " Chart of Accounts
  c_item_fieldname  TYPE uc_fieldname VALUE '/1FB/CS_ITEM',    " FS Item Fieldname
  c_chart_fieldname TYPE uc_fieldname VALUE '/1FB/CS_CHART',   " Chart of Accounts Fieldname
  c_mt_fieldname    TYPE uc_fieldname VALUE '/1FB/MOVE_TYPE'.  " Movement Type Fieldname
  TYPES:
" Item attributes required from BCS databasis
  BEGIN OF s_item,
    /1fb/cs_chart TYPE /bi0/oics_chart,
    /1fb/cs_item TYPE /bi0/oics_item,
    txtmi TYPE uc_txtmi,
    itgrp TYPE uc_itgrp,
    itgrp_max_set TYPE  uc_itgrp_max_set,
  END OF s_item,
  t_item TYPE HASHED TABLE OF s_item WITH UNIQUE KEY /1fb/cs_chart /bic/bcs_litem,
" Breakdown Category attributes required from BCS databasis
  BEGIN OF s_itgrp,
    itgrp TYPE uc_itgrp,
    selid_max TYPE uc_selid,
    txtmi TYPE uc_txtmi,
  END OF s_itgrp,
  t_itgrp TYPE HASHED TABLE OF s_itgrp WITH UNIQUE KEY itgrp,
" Movement Type and Description
  BEGIN OF s_mt_txt,
    move_type TYPE /bi0/oimove_type,
    txtsh TYPE uc_txtsh,
  END OF s_mt_txt,
  t_mt_txt TYPE HASHED TABLE OF s_mt_txt WITH UNIQUE KEY move_type.
  DATA:
" BCS Interfaces
  do_factory        TYPE REF TO if_ug_md_factory,
  do_char           TYPE REF TO if_ug_md_char,
  do_value          TYPE REF TO if_ug_md_char_value,
  do_area           TYPE REF TO if_uc_area,
  do_model          TYPE REF TO if_uc_model,
  do_context        TYPE REF TO if_uc_context,
  do_char_itgrp     TYPE REF TO if_ug_md_char,
  lt_field_val      TYPE ugmd_ts_field_val,
  ls_field_val      TYPE ugmd_s_field_val,
  lt_value          TYPE uc0_ts_value,
  ls_value          TYPE uc0_s_value,
  lt_itgrp          TYPE t_itgrp,
  ls_itgrp          TYPE s_itgrp,
" Lookup tables
  lt_sel            TYPE ugmd_ts_sel,
  ls_sel            TYPE ugmd_s_sel,
  lt_fieldname      TYPE ugmd_ts_fieldname,
  ls_fieldname      TYPE fieldname,
  ls_item           TYPE s_item,
  ls_item2          TYPE s_item,
  lt_item           TYPE t_item,
  lt_mt_txt         TYPE t_mt_txt,
  ls_mt_txt         TYPE s_mt_txt,
  l_tabname         TYPE tabname,
  l_itgrp           TYPE uc_itgrp,
" Output tables
  lt_lookup_bdc     TYPE STANDARD TABLE OF zsbcs_movement_type_lookup_bdc,
  lt_lookup         TYPE STANDARD TABLE OF zsbcs_movement_type_lookup,
  ls_lookup_bdc     TYPE zsbcs_movement_type_lookup_bdc,
  ls_lookup         TYPE zsbcs_movement_type_lookup.
" Initialize BCS interfaces
  IF do_area IS INITIAL.
    CALL METHOD cl_uc_area=>if_uc_area~get_area_instance
      EXPORTING
        i_area  = c_area
      IMPORTING
        eo_area = do_area.
  ENDIF.
  IF do_model IS INITIAL.
    CALL METHOD do_area->get_model
      IMPORTING
        eo_model = do_model.
  ENDIF.
  IF do_factory IS NOT BOUND.
    CALL METHOD cl_uc_area=>if_uc_area~get_md_factory
      EXPORTING
        i_area        = c_area
      IMPORTING
        eo_md_factory = do_factory.
  ENDIF.
" Create reference to FS Item characteristic
  do_char = do_factory->get_char_instance(
      i_fieldname = c_item_fieldname ).
" Define restrictions on FS Item for reading values
" Always filter on chart of accounts
  ls_sel-fieldname = c_chart_fieldname.
  ls_sel-sign      = uc00_cs_ra-sign_i.
  ls_sel-option    = uc00_cs_ra-option_eq.
  ls_sel-low       = c_chart.
  INSERT ls_sel INTO TABLE lt_sel.
" filter on FS Item if provided as input parameter
  IF NOT i_item IS INITIAL.
    ls_sel-fieldname = c_item_fieldname.
    ls_sel-sign      = uc00_cs_ra-sign_i.
    ls_sel-option    = uc00_cs_ra-option_eq.
    ls_sel-low       = i_item.
    INSERT ls_sel INTO TABLE lt_sel.
  ENDIF.
" Get FS Item values
  CALL METHOD do_char->read_value
    EXPORTING
      it_sel   = lt_sel
    IMPORTING
      et_value = lt_item.
" Exit if invalid item was passed as parameter
  if lines( lt_item ) = 0.
    raise no_data.
  endif.
" Additional logic for next finding ITGRP details, etc.........
Would recommend debugging these two methods to get an idea of what BCS is doing:
cl_uc_tx_data_change->if_uc_tx_data_change~analyze_and_add_data
cl_uc_tx_data_change->save_data
Anyway, hope that helps.  It took me a lot of debugging to figure out exactly which objects were being used by the posting process, getting the refresh right (delete/reverse existing documents based on special version customizing), etc.  I wouldn't recommend slamming them into the cube and ODS directly with a RSDRI_CUBE_WRITE_PACKAGE or anything...
- Chris