Linking from a cell to a workbook sheet

Question

I know in Numbers I can set the text in a cell to be a hyperlink to a webpage or an email message--- but is there any way I can set it so that when it's clicked it will take me to another page in the same workbook?  If not, is there another way I can approximate that function (creating a "button" or something)?  Been trying to figure this out a while...

Answer 1

I had some minutes available.
Here is the new script:
--[SCRIPT gotoRange]
Enregistrer le script en tant que Script : gotoRange.scpt
déplacer le fichier créé dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:Numbers:
Il vous faudra peut-être créer le dossier Numbers et peut-être même le dossier Applications.
Placez le curseur dans la table de travail
menu Scripts > Numbers > gotoRange
Dans le dialogue affiché, sélectionnez le groupe de cellules que vous voulez atteindre.
+++++++
Save the script as Script : gotoRange.scpt
Move the newly created file into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Numbers:
Maybe you would have to create the folder Numbers and even the folder Applications by yourself.
Put the cursor in the table to use
menu Scripts > Numbers > gotoRange
In the displayed dialog select the range to reach.
Yvan KOENIG (VALLAURIS, France)
2009/11/13
property theApp : "Numbers"
property targetList : {"A1:A11", "A12:A31", "A32:A69", "A70:A115"}
(* adjust this list to fit your needs *)
--=====
on run
if my parleAnglais() then
set cible to choose from list targetList with prompt "Select a destination’s cell reference"
else
set cible to choose from list targetList with prompt "Choisir la référence de la cellule cible"
end if
if cible is false then error number -128
set cible to item 1 of cible
set {dName, sName, tName, rname} to my getSelection()
if rname is missing value then
if my parleAnglais() then
error "No selected cell !"
else
error "Pas de cellule sélectionnée !"
end if
end if -- rname…
my doYourDuty(dName, sName, tName, cible)
end run
--=====
on doYourDuty(d, s, t, c)
try
tell application "Numbers" to tell document d to tell sheet s to tell table t
set selection range to range c (* try to select the range *)
end tell
on error
if my parleAnglais() then
error "Range “" & c & "” unavailable !"
else
error "Groupe de cellules « " & c & "» inexistant !"
end if
end try
set c to item 1 of my decoupe(c, ":")
tell application "Numbers" to tell document d to tell sheet s to tell table t
set selection range to cell c (* Select the first cell of the range *)
end tell
end doYourDuty
--=====
on getSelection()
local mySelectedRanges, sheetRanges, thisRange, _, myRange, myTable, mySheet, myDoc, mySelection
tell application "Numbers" to tell document 1
set mySelectedRanges to selection range of every table of every sheet
repeat with sheetRanges in mySelectedRanges
repeat with thisRange in sheetRanges
if contents of thisRange is not missing value then
try
thisRange as text
on error errMsg number errNum
set {_, myRange, _, myTable, _, mySheet, _, myDoc} to my decoupe(errMsg, quote)
return {myDoc, mySheet, myTable, myRange}
end try
end if -- contents…
end repeat -- thisRange
end repeat -- sheetRanges
end tell -- document 1 of application
return {missing value, missing value, missing value, missing value}
end getSelection
--=====
on decoupe(t, d)
local l
set AppleScript's text item delimiters to d
set l to text items of t
set AppleScript's text item delimiters to ""
return l
end decoupe
--=====
on parleAnglais()
local z
try
tell application theApp to set z to localized string "Cancel"
on error
set z to "Cancel"
end try
return (z is not "Annuler")
end parleAnglais
--=====
--[/SCRIPT]
Yvan KOENIG (VALLAURIS, France) vendredi 13 novembre 2009 13:59:16