Lr_selections- get_selected_rows returns zero entries Follow-Up Question...

Question

Hello SDN Community,
I was able to get a list of row numbers returned from GET_SELECTED_ROWS when I added a call to GET_METADATA.
However, GET_SELECTED_ROWS only works the first time.  When I return to the screen, the lines are still highlighted and if I click the button again, it goes thru the code but won't return the row numbers. 
If I back up to the previous screen and come forward to the ALV grid screen, the rows are still highlighted and when i click the button, no row numbers are returned.
I do not understand why the rows remain highlighted in the grid.  I tried the grid->refresh method, but that does not clear the highlighting.  I can't help but think that maybe if I could figure out how to get the highlighted lines to go away, that maybe GET_SELECTED_ROWS would start working again.
Or maybe I need to do something else for GET_SELECTED_ROWS to start working again?
Your thoughts and insights are appreciated!
Thank you,
Dean Atteberry.

Answer 1

Hi,
Not sure ...what you are missing...I tried this code..and it returns the correct set of rows...even if click the button to get the rows...multiple times...
please check this sample.
DATA: g_container TYPE scrfname VALUE 'CONTAINER1'.
DATA: g_custom_container TYPE REF TO cl_gui_custom_container.
TYPES: BEGIN OF type_output,
         matnr TYPE matnr,
       END OF type_output.
DATA:lt_output   TYPE STANDARD TABLE OF type_output,
     lwa_rows    TYPE int4,
     lwa_output  TYPE type_output,
     lt_rows     TYPE salv_t_row.
* Local declarations.
DATA: lr_table      TYPE REF TO cl_salv_table,
      lr_selections TYPE REF TO cl_salv_selections.
DATA: lr_columns    TYPE REF TO cl_salv_columns_table.
DATA: lr_grid       TYPE REF TO cl_gui_alv_grid.
START-OF-SELECTION.
* Prepare data.
  lwa_output-matnr = 'TEST1'.APPEND lwa_output TO lt_output.
  lwa_output-matnr = 'TEST2'.APPEND lwa_output TO lt_output.
  lwa_output-matnr = 'TEST3'.APPEND lwa_output TO lt_output.
  CALL SCREEN 100.
*       MODULE PBO OUTPUT                                             *
MODULE pbo OUTPUT.
  SET PF-STATUS 'TEST'.
  IF g_custom_container IS INITIAL.
    CREATE OBJECT g_custom_container
      EXPORTING
        container_name = g_container.
* Call the factory method
    TRY.
        cl_salv_table=>factory(
          EXPORTING
            r_container = g_custom_container
            container_name = 'CONTAINER1'
          IMPORTING
            r_salv_table = lr_table
          CHANGING
            t_table      = lt_output ).
      CATCH cx_salv_msg.                                "#EC NO_HANDLER
    ENDTRY.
* Column selection
    lr_selections = lr_table->get_selections( ).
    lr_selections->set_selection_mode( if_salv_c_selection_mode=>row_column ).
    lr_columns = lr_table->get_columns( ).
    lr_columns->set_optimize( abap_true ).
* Display
    lr_table->display( ).
  ENDIF.
ENDMODULE.                    "pbo OUTPUT
*       MODULE PAI INPUT                                              *
MODULE pai INPUT.
  CASE sy-ucomm.
    WHEN 'EXIT' OR 'BACK'.
      PERFORM exit_program.
    WHEN 'GET_ROWS'.
      CALL METHOD lr_table->get_metadata.  " call this method....
* Get the selected rows.
      lt_rows = lr_selections->get_selected_rows( ).
* Display the selected rows.
      BREAK-POINT.          " break point.
      LOOP AT lt_rows INTO lwa_rows.
        READ TABLE lt_output INTO lwa_output INDEX lwa_rows.
        WRITE: / lwa_output-matnr.
      ENDLOOP.
  ENDCASE.
ENDMODULE.                    "pai INPUT
*       FORM EXIT_PROGRAM                                             *
FORM exit_program.
  LEAVE PROGRAM.
ENDFORM.                    "exit_program
Thanks
Naren