Mailing details to our seniorguy after filling screen fields.

Question

hi
i have screen in modulepool programming in that screen i have a screen fields of empno,empname,salary,medicalbill,allowance etc after filling these details by an employee and if he click (mail)  pushbutton the screen fields with values will submitted to his senior guy as a mail .pls send suggestions.
thankful to all,
regards
srinivasulu.

Answer 1

Hi Srini,
Have a look at the code for sending mail :-
*&      Form  send_mail_to_promotion
*       TO SEND MAIL TO PROMOTION SECTION
*      -->PF_PERNR  pa0000-pernr
*      -->PF_BEGDA  pa0000-begda
*      -->PF_RANK   pa9007-rankcd
FORM send_mail_to_promotion  USING  value(pf_pernr) TYPE pa0000-pernr
                                    value(pf_begda) TYPE pa0000-begda
                                    value(pf_rank)  TYPE pa9007-rankcd.
  DATA: lt_objcont    LIKE solisti1 OCCURS 10 WITH HEADER LINE,
        lt_reclist    LIKE somlreci1 OCCURS 5 WITH HEADER LINE,
        lf_doc_chng   LIKE sodocchgi1,
        lf_entries    LIKE sy-tabix,
        lf_name       TYPE pa0001-ename.
* Fill the document
  lf_doc_chng-obj_name = 'URGENT'.
  lf_doc_chng-obj_descr = 'Update Promotion Status!'.
  lf_doc_chng-sensitivty = 'P'.
  lt_objcont = 'Promotion order has been issued for the person'.
  APPEND lt_objcont.
  CONCATENATE 'Date:' pf_begda
              INTO lt_objcont SEPARATED BY space.
  APPEND lt_objcont.
  CONCATENATE 'Personnel Number:' pf_pernr
              INTO lt_objcont SEPARATED BY space.
  APPEND lt_objcont.
  CLEAR lf_name.
  SELECT SINGLE ename
  INTO lf_name
  FROM pa0001
  WHERE pernr = pf_pernr.
  CONCATENATE 'Person Name:' lf_name
              INTO lt_objcont SEPARATED BY space.
  APPEND lt_objcont.
  CONCATENATE 'Rank:' pf_rank
              INTO lt_objcont SEPARATED BY space.
  APPEND lt_objcont.
  lt_objcont = 'Please update rank of the person'.
  APPEND lt_objcont.
  lf_entries = LINES( lt_objcont ).
  READ TABLE lt_objcont INDEX lf_entries.
  lf_doc_chng-doc_size = ( lf_entries - 1 ) * 255 +
                         STRLEN( lt_objcont ).
* Fill the receiver list
  CLEAR lt_reclist.
* NOTE::
* REPLACE THIS LINE WITH LOGIN OF PROMOTION SECTION
  lt_reclist-receiver = 'RAJESH'.  " replace with <login name>
* ::ETON
  lt_reclist-rec_type = 'B'.
  lt_reclist-express = 'X'.
  APPEND lt_reclist.
* Send the document
  CALL FUNCTION 'SO_NEW_DOCUMENT_SEND_API1'
    EXPORTING
      document_type              = 'RAW'
      document_data              = lf_doc_chng
*      put_in_outbox              = 'X'
    TABLES
      object_content             = lt_objcont
      receivers                  = lt_reclist
    EXCEPTIONS
      too_many_receivers         = 1
      document_not_sent          = 2
      document_type_not_exist    = 3
      operation_no_authorization = 4
      parameter_error            = 5
      x_error                    = 6
      enqueue_error              = 7.
ENDFORM.                    " send_mail_to_promotion
Hope it solves your problem.
Regards,
Manish Joshi
Don't tell me, you don't know how to award points.