Matrix Raised to a Power in Excel

Question

To Whom it May Concern,
I am working with matrices in Excel 2010 and happened upon a problem.  Excel can perform matrix multiplication (e.g. A1:B2 times A3:B4) by the mmult function and yields the correct answer.  However, there is a problem when attempting to raise a
single matrix to a power - e.g. A^3 (for some array I refer to as A).
Various fora online all suggest using the power function on an array (thus, using the ctrl + shift + enter).  This takes each entry of the matrix and raises it to the given power.  This is NOT the same as raising the matrix to the given power,
and thus yields an incorrect result if the user is hoping to perform such an operation.  Effectively, I'm curious as to the existence of an excel function that uses the method of mmult for raising a matrix to a power.
I'm not sure if this is an error in an excel function or something that exists in an add on.  Please let me know if there is a way to properly raise a matrix to a power in excel.
Thanks,
Louis

Answer 1

Well, you can make your own simple matrix power function, like this;
Function PowerMatrix(rngInp As Range, lngPow As Long) As Variant
Dim i As Long
PowerMatrix = rngInp
If lngPow > 1 Then
For i = 2 To lngPow
PowerMatrix = Application.WorksheetFunction.MMult(rngInp, PowerMatrix)
Next
End If
End Function
Use it in a range like;
=PowerMatrix(A1:B2,3)
to get the matrix to the third power. Enter the function as an array formula.
This simple function does not test for a square matrix (which you need if you are going to multiply a matrix by itself).
Ed Ferrero
www.edferrero.com
I know this is an ancient post but there is a much better answer. If you want to raise the matrix to a large power (like 1 billion), the above will leave you waiting for a long time. Note that X^100 can be represented as (X^64)*(X^32)*(X^4) = (X^2^2) * (X^2^2^2^2^2)
* (X^2^2^2^2^2^2). By repeatedly squaring and multiplying the squares by the output value you can drastically reduce the number multiplications required.
Function PowerMatrix(Matrix As Range, Power As Long) As Variant
Dim Result As Variant
Dim Square As Variant
Dim i As Long
Square = Matrix
For i = 0 To 31
If (Power And 2 ^ i) Then
If IsEmpty(Result) Then
Result = Square
Else
Result = Application.WorksheetFunction.MMult(Square, Result)
End If
End If
If 2 ^ i >= Power Then Exit For
Square = Application.WorksheetFunction.MMult(Square, Square)
Next
PowerMatrix = Result
End Function