MDB / AQ / RA problem: message not dequeued when put by PL/SQL to AQ

Question

I’m facing the following problem: I have a setup a J2CA Resource Adapter for AQ (OEMS) and a MDB listener. As polling configuration I use the following:
<config-property>
<config-property-name>ListenerThreadMaxPollInterval</config-property-name>
<config-property-value>250</config-property-value>
</config-property>
According to the spec, this configuration should make sure that the underlying the JMS implementation polls the queue (AQ) every 250 ms in order to check whether there are available message.
When I send a message to the AQ using JMS, the message is dequeued within an acceptable time range.
However, when PL/SQL code enqueues messages directly to the AQ things do not work well:
1. When PL/SQL posts a message > 4096 kb (according to the spec messages > 4096 kb have to be posted in a different way, since a CLOB column is used) for the first time it takes about 4 minutes until the MDB picks it up. All subsequent messages are picked up immediately, which is not surprisingly since the documentation mentions that an adaptive strategy is used. 4 minutes is not acceptable for me.
2. When PL/SQL posts a message < 4096 kb the message expires on the AQ-queue (even though it is a non-expirable message), without being picked up by the MDB.
What do I do wrong? Help is needed and appreciated!

Answer 1

With great pleasure I can announce 'a' solution for the problem stated. Apparently the JMS implementation expects certain JMS headers in the Oracle AQ message in order to fetch it from the AQ properly. The PL/SQL code, which caused the problem described in this post, looked like this:
declare
enqueue_options SYS.DBMS_AQ.enqueue_options_t;
message_properties SYS.DBMS_AQ.message_properties_t;
message_handle RAW (16);
user_prop_array SYS.aq$_jms_userproparray;
AGENT SYS.aq$_agent;
header SYS.aq$_jms_header;
MESSAGE SYS.aq$_jms_text_message;
p_xml_intern_bericht                          varchar2(8000);
p_len_message                                    number;
begin
--p_xml_intern_bericht :='bla';
p_xml_intern_bericht :='test';
p_len_message := LENGTH (p_xml_intern_bericht);
dbms_output.put_line('->' ||p_len_message);
IF p_len_message > 4000
THEN
MESSAGE := SYS.aq$_jms_text_message (header,p_len_message,NULL,p_xml_intern_bericht);
ELSE
MESSAGE :=SYS.aq$_jms_text_message (header,p_len_message,p_xml_intern_bericht,NULL);
     END IF;                                        
DBMS_AQ.enqueue (queue_name => 'MY_AQ' ,
enqueue_options => enqueue_options,
message_properties => message_properties,
payload => MESSAGE,
msgid => message_handle
COMMIT;
end;
After adding the required JMS headers as in the snipped below, the message was picked up immediately from the AQ:
declare
msg SYS.AQ$_JMS_TEXT_MESSAGE;
msg_hdr SYS.AQ$_JMS_HEADER;
msg_agent SYS.AQ$_AGENT;
msg_proparray SYS.AQ$_JMS_USERPROPARRAY;
msg_property SYS.AQ$_JMS_USERPROPERTY;
queue_options DBMS_AQ.ENQUEUE_OPTIONS_T;
msg_props DBMS_AQ.MESSAGE_PROPERTIES_T;
msg_id RAW(16);
dummy VARCHAR2(4000);
begin
msg_agent := SYS.AQ$_AGENT('', null, 0);
msg_proparray := SYS.AQ$_JMS_USERPROPARRAY();
msg_proparray.EXTEND(1);
msg_property := SYS.AQ$_JMS_USERPROPERTY('JMS_OracleDeliveryMode', 100, '2', NULL, 27);
msg_proparray(1) := msg_property;
msg_hdr := SYS.AQ$_JMS_HEADER(msg_agent,null,'MY_SCHEMA',null,null,null,msg_proparray);
msg := SYS.AQ$_JMS_TEXT_MESSAGE(msg_hdr,null,null,null);
msg.text_vc := 'test';
msg.text_len := length(msg.text_vc);
DBMS_AQ.ENQUEUE( queue_name => 'MY_AQ'
, enqueue_options => queue_options
, message_properties => msg_props
, payload => msg
, msgid => msg_id);     
commit;
end;     
This solution was posted in the following blog: http://technology.amis.nl/blog/?p=2384. The environment in this blog is a Oracle XE database. The writer gets an ERROR when posting a message without adding the described JMS headers (see first pl/sql code snippet). Therefore he was forced to provide them in order to make AQ work for him.
The remarkable thing is that in our environment (Oracle 10.2.0.x) posting messages without the necessary JMS headers do not result in errors. The AQ accepts them but the JMS listener remains silent or receives them after an unacceptable amount of time.
This must definitely be a bug. Hope this information can help you to solve your PL/SQL AQ JMS problem.