Method CMD_EI_API MAINTAIN does not commit

Question

Hi gurus,
I tried to use the method MAINTAIN in the class CMD_EI_API to create a new customer, I tried both from transaction se24 and from a report to call it. No error message and a new customer number generated but when a look for it in transaction  XD03 I get the error message: Customer 10002 has not been created.
Any help will be appreciate
Leo

Answer 1

Hi ABAPers,
this is my example code for updating two KNVV-fields of a single customer.
As you might notice, one of the fields is a ZZ-field, which requires to do some additional
work to get it updated (Refer to my post at [CMD_EI_API usage together with KNVV append;).
Regards
Daniel Klein
    DATA  is_master_data  TYPE cmds_ei_main.
    DATA: es_master_data  TYPE cmds_ei_main.
    DATA: es_error        TYPE cvis_message.
    DATA: wa_customers    TYPE cmds_ei_extern.
    DATA: lt_sales        TYPE cmds_ei_sales_t.
    DATA: wa_sales        LIKE LINE OF lt_sales.
* Check obligatory fields for KNVV
    CHECK gp_vkorg IS NOT INITIAL AND gp_vtweg IS NOT INITIAL
      AND gp_spart IS NOT INITIAL.
* Control parameters
      wa_customers-header-object_instance-kunnr = '0006206900'.    "customer number
      wa_customers-header-object_task = 'U'.                       "update customer
      APPEND wa_customers TO is_master_data-customers.
* Read customer
      cmd_ei_api_extract=>get_data( EXPORTING is_master_data = is_master_data
                                    IMPORTING es_master_data = es_master_data ).
* Change the read-data
      CLEAR is_master_data.
      is_master_data = es_master_data.
      READ TABLE is_master_data-customers INDEX 1 INTO wa_customers.
      DELETE is_master_data-customers INDEX 1.
      lt_sales = wa_customers-sales_data-sales.
      READ TABLE lt_sales WITH KEY  data_key-vkorg = gp_vkorg
                                    data_key-vtweg = gp_vtweg
                                    data_key-spart = gp_spart
                                    INTO wa_sales .
      wa_sales-data-kvgr1 = 'BB'.                       "new field value
      wa_sales-datax-kvgr1 = abap_true.                 "flag: change this field
      wa_sales-data-zzbemerkung = 'MAINTAIN-Bemerkung'. "new field value
      wa_sales-datax-zzbemerkung = abap_true.           "flag: change this field
      wa_sales-task = 'U'.                              "Maintaining-mode: update
      CLEAR wa_customers-sales_data-sales.
      APPEND wa_sales TO wa_customers-sales_data-sales.
      APPEND wa_customers TO is_master_data-customers.
* Testing update on customer
      cmd_ei_api=>maintain( EXPORTING is_master_data = is_master_data
                            IMPORTING es_error = es_error ).
      IF es_error-is_error IS INITIAL.
*  No errors? Commit work
        CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
          EXPORTING
            wait = abap_true.
      ELSE.
        CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
      ENDIF.
Edited by: D. Klein [GER] on Nov 18, 2011 3:16 PM + Rollback