Moving Folders Version 2. Please Help!

Question

Hello again,
Once again I need your help with the same script but I just need a little more help.  I'm an (very) amateur scripter and I'm still trying to grasp the fundementals.  This time I need your help, so that I can also move files as well as folders.  Here is my script so far, but it doesn't seem to be working.  Pretty much I want to make it so that if I click on Files it will do the same exact thing it does for folders, but with files.
repeat
          set theChoice to the button returned of (display dialog "Welcome to Cargo.  We make it easier to move multiple folders to a specific destination.  Would you like to move files or folders?" buttons {"Files", "Folders", "Cancel"})
          repeat
                    repeat
                              if theChoice is {"Folders"} then set srclist to choose folder with prompt "Choose the folder(s) you want to move" with multiple selections allowed
                              if theChoice is {"Folders"} then set dst to choose folder with prompt "Choose the destination folder"
                              if theChoice is {"Folders"} then if {dst} is in srclist then
                                        display dialog "The destination cannot be in the source list."
                              else
                                        exit repeat
                              end if
                    end repeat
  --return {srclist, dst} -- for test
                    tell application "Finder"
  move srclist to dst
                    end tell
                    display dialog "Made by Connor Devlin.  If you find any bugs please contact me at [email protected].  If you liked this app share it with your friends.  ©McKeever Software."
          end repeat
end repeat
Problem 1: Nothing seems to happen when I click run.
Problem 2: I'm not sure how to make it so that ONLY if you click Folders will it do the process to move folders.
Problem 3: I'm not sure how to make it so that ONLY if you click Files will it do the process to move files.
Problem 4: It does not seem to recognize the variable dst or srclist.
I apprecaite all help

Answer 1

You seem to be stuck on using individual if..then statements instead of arranging your statements into logical groups (and the 'repeat forever' loops can get you into trouble as well).  In this case, if the choice is for files you aren't geting new source and destination choices (if you have already made the source and destination choices those will be used again, most likely resulting in a error).
The solution is to use the result of the first dialog to set whether the source items are files or folders, instead of that extra 'repeat forever' loop.
repeat -- forever (at least until canceled)
     set theChoice to the button returned of (display dialog "Welcome to Cargo.  We make it easier to move multiple folders to a specific destination.  Would you like to move files or folders?" buttons {"Files", "Folders", "Cancel"})
     if theChoice is "Folders" then
          set srclist to choose folder with prompt "Choose the folders you want to move" with multiple selections allowed
     else -- files
          set srclist to choose file with prompt "Choose the files you want to move" with multiple selections allowed
     end if
     repeat -- until valid destination
          set dst to choose folder with prompt "Choose the destination folder"
          if dst is in srclist then
               display dialog "The destination cannot be in the source list."
          else
               exit repeat
          end if
     end repeat
     log "moving:"
     log srclist
     log "to:  " & dst
     tell application "Finder"
          move srclist to dst
     end tell
     display dialog "Made by Connor Devlin.  If you find any bugs please contact me at [email protected].  If you liked this app share it with your friends.  ©McKeever Software." buttons {"Again", "OK"} cancel button "OK" default button 2
end repeat