MUSIC ON SELECTION-SCREEN

Question

Can we put .mp3 or any other format file on selection-screen????

Answer 1

Hi, Ritesh
Test the Sample Code Below hope it will help you regarding your requirements.
DATA: it_filetable        TYPE filetable,
      wa_filetable        LIKE LINE OF it_filetable,
      default_extension   TYPE string,
      rc                  TYPE i.
SELECTION-SCREEN: BEGIN OF LINE.
SELECTION-SCREEN: COMMENT 1(20) cpfilen FOR FIELD pfilen.
PARAMETERS: pfilen TYPE string.
SELECTION-SCREEN PUSHBUTTON 72(15) play USER-COMMAND play VISIBLE LENGTH 3.
SELECTION-SCREEN: END OF LINE.
AT SELECTION-SCREEN.
  IF sy-ucomm = 'PLAY'.
    CALL METHOD cl_gui_frontend_services=>execute
      EXPORTING
        document               = pfilen
        minimized              = 'X'
      EXCEPTIONS
        cntl_error             = 1
        error_no_gui           = 2
        bad_parameter          = 3
        file_not_found         = 4
        path_not_found         = 5
        file_extension_unknown = 6
        error_execute_failed   = 7
        synchronous_failed     = 8
        not_supported_by_gui   = 9
        OTHERS                 = 10.
    IF sy-subrc NE 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                 WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
  ENDIF.
INITIALIZATION.
  cpfilen = 'Select Music File'.
  CALL FUNCTION 'ICON_CREATE'
    EXPORTING
      name                  = 'ICON_WORKFLOW_ACTIVITY'
      info                  = 'Play'
      add_stdinf            = 'X'
    IMPORTING
      RESULT                = play
    EXCEPTIONS
      icon_not_found        = 1
      outputfield_too_short = 2
      OTHERS                = 3.
  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR pfilen.
  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    EXPORTING
      window_title            = 'Select File'
    CHANGING
      file_table              = it_filetable
      rc                      = rc
    EXCEPTIONS
      file_open_dialog_failed = 1
      cntl_error              = 2
      error_no_gui            = 3
      not_supported_by_gui    = 4
      OTHERS                  = 5.
  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ELSE.
    READ TABLE it_filetable INTO wa_filetable INDEX 1.
    IF sy-subrc = 0.
      pfilen = wa_filetable-filename.
    ENDIF.
  ENDIF.
Thanks and Best Regards,
Faisal
Edited by: Faisal Altaf on Dec 4, 2010 11:52 AM