Need help with script - either shell or applescript

Question

ok, so what i want to do is make some sort of script, either applescript or shell script, that will do the following:
take out from a command in the terminal
put that output into a text file already on my computer.
the only thing is that i need to put the output in the file kinda weird: i need to take it and put each character of output on a new line, but not create new lines
example:
take output of command 'uptime' (up 32 days, 23:09)
place in file 'myFile'
output:
key u
key p
key space
key 3
key 2
key space
key d
anyone have any idea on how to do this?
thanks in advance

Answer 1

OK, here is the new one, it will go through the existing text, replacing the text between the specified stopping and starting lines with the shell script text:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFDDFF;
overflow: auto;"
title="this text can be pasted into the Script Editor">
-- get the file to write to
property MyFile : missing value -- the file to write to (alias)
if MyFile is missing value then set MyFile to (choose file with prompt "select a file to write to:" default location (path to desktop) without invisibles)
-- get the data
set {TempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, ","}
set MyText to the first text item of (do shell script "uptime") -- just get the uptime part
set AppleScript's text item delimiters to ""
set {MyText, AppleScript's text item delimiters} to {the text items of MyText, TempTID} -- get the characters
-- add text to each character of the data
repeat with AnItem from 1 to (count MyText)
if item AnItem of MyText is " " then
set item AnItem of MyText to "key space" -- expand the space character
else
set item AnItem of MyText to "key " & item AnItem of MyText
end if
end repeat
-- show the result
choose from list MyText with prompt "the following results will be written:" with empty selection allowed
if result is false then return -- exit
-- make the new file
set OldFile to paragraphs of (read MyFile) -- read the old file
set NewFIle to {} -- this will be the contents of the new file
set ReadOrNot to true
repeat with SomeLine in OldFile -- step through each line
set SomeLine to the contents of SomeLine
if SomeLine is equal to "key n" then -- stop copying lines
-- set the end of NewFIle to SomeLine -- include the stop line
set ReadOrNot to false
set NewFIle to NewFIle & MyText -- add the data text
else if SomeLine is equal to "key Down Arrow" then -- start copying lines again
-- set the end of NewFIle to SomeLine -- include the start line
set ReadOrNot to true
else if ReadOrNot then -- add lines only if we are copying
set the end of NewFIle to SomeLine
end if
end repeat
-- write the new results to the file
try
set TheOpenFIle to (open for access MyFile with write permission)
set eof TheOpenFIle to 0 -- write over the existing contents
repeat with SomeLine in NewFIle
write SomeLine & return to TheOpenFIle
end repeat
close access TheOpenFIle
on error ErrorMessage number ErrorNumber -- oops
log space & (ErrorNumber as text) & ":" & tab & ErrorMessage
try
close access TheOpenFIle
end try
end try
</pre>
I didn't know if you wanted to include the stop and start lines, so just uncomment the appropriate statement(s) if you want to include them. I left the stop line comparison as "key n", change it to your number (or some unique text string if you only want one specific replacement).