Optimize Clob concatenation

Question

Hi, I have a stored proc that return a string containing a concatenation of the result of a select on a unique column.
The code is about the following :
CREATE OR REPLACE PROCEDURE pGetAllProductSpec (ProdId in Varchar2 , CaracLob out clob) IS
len BINARY_INTEGER := 32767;
CURSOR c1 (prod_id varchar2) IS
     SELECT PRODUCT_SPEC FROM PRODUCT_SPECIFICATION
     WHERE PRODUCT_ID = prod_id ;
BEGIN
DBMS_LOB.CREATETEMPORARY(Caraclob, TRUE);
FOR product_carac IN c1( ProdId) LOOP
len:=length(product_carac.PRODUCT_SPEC);
dbms_lob.WRITEAPPEND(CaracLob, len, product_carac.PRODUCT_SPEC);
END LOOP;
END;
It works quite well, but I find that the loop to concatenate the result take too much time.
I need a Clob because, I don't know exactly the length of the result
I would like to optimize it. Has anyone a suggest ?

Answer 1

Also, benchmark the use of bulk operations to see if you can benefit.
SQL> DECLARE
  2      vclob        CLOB;
  3      vchar_buffer VARCHAR2(32767);
  4  BEGIN
  5      dbms_lob.createtemporary(vclob,
  6                               cache => TRUE);
  7      vchar_buffer := NULL;
  8
  9      FOR rec IN (SELECT text FROM all_source)
10      LOOP
11          IF length(vchar_buffer) + length(rec.text) > 32767
12          THEN
13              dbms_lob.writeappend(vclob,
14                                   length(vchar_buffer),
15                                   vchar_buffer);
16              vchar_buffer := NULL;
17          END IF;
18          vchar_buffer := vchar_buffer || rec.text;
19      END LOOP;
20      dbms_lob.writeappend(vclob,
21                           length(vchar_buffer),
22                           vchar_buffer);
23  END;
24  /
PL/SQL procedure successfully completed.
Elapsed: 00:00:01.13
SQL> DECLARE
  2      vclob        CLOB;
  3      vchar_buffer VARCHAR2(32767);
  4      CURSOR cur IS
  5          SELECT text FROM all_source;
  6      TYPE rec_table IS TABLE OF VARCHAR2(4000) INDEX BY BINARY_INTEGER;
  7      rec_tab rec_table;
  8  BEGIN
  9      dbms_lob.createtemporary(vclob,
10                               cache => TRUE);
11      vchar_buffer := NULL;
12
13      OPEN cur;
14      LOOP
15          rec_tab.DELETE;
16          FETCH cur BULK COLLECT
17              INTO rec_tab LIMIT 100;
18          FOR idx IN 1 .. rec_tab.COUNT
19          LOOP
20              IF length(vchar_buffer) + length(rec_tab(idx)) > 32767
21              THEN
22                  dbms_lob.writeappend(vclob,
23                                       length(vchar_buffer),
24                                       vchar_buffer);
25                  vchar_buffer := NULL;
26              END IF;
27              vchar_buffer := vchar_buffer || rec_tab(idx);
28          END LOOP;
29          EXIT WHEN cur%NOTFOUND ;
30      END LOOP;
31      CLOSE cur;
32      dbms_lob.writeappend(vclob,
33                           length(vchar_buffer),
34                           vchar_buffer);
35  END;
36  /
PL/SQL procedure successfully completed.
Elapsed: 00:00:00.70
SQL>