Passing large number of parameters

Question

In chapter 6 of the reports 6i documentation it states that one of the advantages of using a ref cursor is to "avoid the use of lexical parameters in your reports". I am not clear how it does this. Can anyone explain how this would work?
In my application, I would like to print an exception report (ie use run_report) when an item in the base report exceeds a threshold amount. I would rather not pass all the subtotal values, as that would require passing a large number of parameters to the exception report. I can do it, but it seems like there should be an easier way. Passing a parameter of type RECORD would do it, but isn't allowed, right?
null

Answer 1

1. In some cases, you can avoid the use of lexical parameters in your reports
with "static" ref cursor.
Example for "static" ref cursor:
1.1 Stored package
CREATE OR REPLACE PACKAGE report_static IS
TYPE type_ref_cur_sta IS REF CURSOR RETURN dept%ROWTYPE;
FUNCTION func_sta (p_order_by VARCHAR2) RETURN type_ref_cur_sta;
END;
CREATE OR REPLACE PACKAGE BODY report_static IS
FUNCTION func_sta (p_order_by VARCHAR2) RETURN type_ref_cur_sta IS
ref_cur_sta type_ref_cur_sta;
BEGIN
IF p_order_by = 'dname' THEN
OPEN ref_cur_sta FOR
SELECT * FROM dept ORDER BY dname;
ELSE
OPEN ref_cur_sta FOR
SELECT * FROM dept ORDER BY deptno;
END IF;
RETURN ref_cur_sta;
END;
END;
1.2 Query PL/SQL in Reports
function QR_1RefCurQuery return report_static.type_ref_cur_sta is
begin
return report_static.func_sta (:p_order_by);
end;
2. But if you need (for example) dynamic where, you (practically)
can't use "static" ref cursor. In this case, you can use "dynamic" ref cursor
(available from Oracle 8.1.5).
Example for "dynamic" ref cursor (note that Reports need
"static" ref cursor type for building Report Layout):
2.1 Stored package
CREATE OR REPLACE PACKAGE report_dynamic IS
TYPE type_ref_cur_sta IS REF CURSOR RETURN dept%ROWTYPE; -- for Report Layout only
TYPE type_ref_cur_dyn IS REF CURSOR;
FUNCTION func_dyn (p_where VARCHAR2) RETURN type_ref_cur_dyn;
END;
CREATE OR REPLACE PACKAGE BODY report_dynamic IS
FUNCTION func_dyn (p_where VARCHAR2) RETURN type_ref_cur_dyn IS
ref_cur_dyn type_ref_cur_dyn;
BEGIN
OPEN ref_cur_dyn FOR
'SELECT * FROM dept WHERE ' | | NVL (p_where, '1 = 1');
RETURN ref_cur_dyn;
END;
END;
2.2 Query PL/SQL in Reports
function QR_1RefCurQuery return report_dynamic.type_ref_cur_sta is
begin
return report_dynamic.func_dyn (:p_where);
end;
Regards