Passing object and instantiating it dynamically in a procedure

Question

Please tell me how to write the following code?
I am passing objcet name as an input to the procedure.
I want to create the instance of the object dynamically.
Then I want to execute the member function
procedure p1(p_input) is
     l_a varchar2(4000);
begin
     declare
          l_p_input p_input; -- here l_p_input (p_input is the input of
the procedure). p_input is also an
OBJECT I have created
     begin
          l_p_input := p_input(var1,var2);
          dbms_output.put_line(l_p_input.get_data);
     end;
end;

Answer 1

Here's a simplified example. It assumes you get the same number of input parameters from procedure2 every time (i.e. all object types have the same number of attributes). It gives you the basic idea anyway...
SQL> create table calcs (name varchar2(30), method varchar2(30), value number);
Table created.
SQL> create procedure p1( p_name   in varchar2,
  2                       p_method in varchar2,
  3                       p_attr1  in number,
  4                       p_attr2  in number,
  5                       p_attr3  in number ) is
  6
  7     v_value varchar2(32767);
  8
  9  begin
10
11     execute immediate 'declare
12                           o ' || p_name || ' := ' || p_name || '(:1,:2,:3);
13                        begin
14                           :4 := o.' || p_method || ' ;
15                        end;'
16     using in p_attr1, in p_attr2, in p_attr3, out v_value;
17
18     insert into calcs (name, method, value)
19     values (p_name, p_method, v_value);
20
21  end;
22  /
Procedure created.
SQL> create type o1 as object
  2  ( attr1 number
  3  , attr2 number
  4  , attr3 number
  5  , member function addthemup return number
  6  );
  7  /
Type created.
SQL> create type body o1 as
  2     member function addthemup return number is
  3     begin
  4        return self.attr1+self.attr2+self.attr3;
  5     end;
  6  end;
  7  /
Type body created.
SQL> create type o2 as object
  2  ( attr1 number
  3  , attr2 number
  4  , attr3 number
  5  , member function multiplythem return number
  6  );
  7  /
Type created.
SQL> create type body o2 as
  2     member function multiplythem return number is
  3     begin
  4        return self.attr1*self.attr2*self.attr3;
  5     end;
  6  end;
  7  /
Type body created.
SQL> exec p1('O1','ADDTHEMUP',1,2,3);
PL/SQL procedure successfully completed.
SQL> exec p1('O2','MULTIPLYTHEM',10,10,10);
PL/SQL procedure successfully completed.
SQL> select * from calcs;
NAME                           METHOD                              VALUE
O1                             ADDTHEMUP                               6
O2                             MULTIPLYTHEM                         1000Regards