Plz see this and think once..

Question

hai friends,
i got one trouble plz help as soon as u can....imagine i ahve 10000 rows....
i want to upload into one it table and i want to split them into 100 text files..each having the
100 rows...just like splitting them into text files and downloading them as .txt files..plz.help me..

Answer 1

How about something like this.
REPORT  zrich_0001.
DATA: itab1 TYPE STANDARD TABLE OF string.
DATA: itab2 TYPE STANDARD TABLE OF string.
DATA: wa LIKE LINE OF itab1.
DATA: rec_counter TYPE i.
DATA: fil_counter(3) TYPE c.
DATA: file_name TYPE string.
CALL METHOD cl_gui_frontend_services=>gui_upload
  EXPORTING
    filename = 'C:/testfile.txt'
  CHANGING
    data_tab = itab1
  EXCEPTIONS
    OTHERS   = 19.
CLEAR fil_counter.
CLEAR rec_counter.
LOOP AT itab1 INTO wa.
  APPEND wa TO itab2.
  rec_counter = rec_counter + 1.
  IF rec_counter = 100.
    PERFORM download_it.
  ENDIF.
  AT LAST.
    CHECK itab2[] IS NOT INITIAL.
    PERFORM download_it.
  ENDAT.
ENDLOOP.
*&      Form  download_it
*       text
FORM download_it.
  CLEAR file_name.
  fil_counter = fil_counter + 1.
  CONCATENATE 'c:/testfile' fil_counter '.txt' INTO file_name.
  CONDENSE file_name NO-GAPS.
  CALL METHOD cl_gui_frontend_services=>gui_download
    EXPORTING
      filename = file_name
    CHANGING
      data_tab = itab2
    EXCEPTIONS
      OTHERS   = 24.
  CLEAR rec_counter.
  REFRESH itab2.
ENDFORM.                    "download_it
Regards,
Rich Heilman