Printing ZPL (Zebra) data to printer spooler without character conversion

Question

Hi all,
We are printing shipping labels from UPS, with a process where we recive the ZPL label code directly from UPS, and we just need to pass the data to the printer to get the labels. We have already implemented this with Fedex and some custom labels, and it works perfectly. The problem with the UPS label data is that it contains non-printable characters (in the MaxiCode data field). When passed to the SAP printer spooler (see code example below), the data gets corrupted because SAP interprets these non-printable characters as printer control codes.
I have verified this by saving the ZPL data to a local file, before printing it through the SAP spooler. I then print this raw data and compare the output with the labels printed from the spooler. The MaxiCode (the big 2D barcode) is different in these labels. UPS has also tested the labels, and rejected them because of incorrect data in the barcode.
For printing, we are using printers defined as type "PLAIN", but I also tried using the "LZEB2" device type with the same result. The error we see in the spooler entry is this:
Print ctrl S_0D_ is not defined for this printer. Page 1, line 2, col. 2201
Print output may not be as intended
The printer ctrl code differs, depending om the label. I have examined the spooler data in "raw" mode, and there is always an ASCII character 28 (hex 1C) in front of the characters that SAP think are control codes, and this is why I think these non-printable characters are the reason for the problems.
This is the function module I use to print the ZPL data (and as stated above, this works fine for Fedex and custom labels). The ZPL data is converted to binary format before passed to the function module, but I also tried to send the data in text format with another FM, but the result is the same. I have experimented with the "codepage" parameter, and this one gives the least amount of errors, and some labels actually get through without errors. But still at least 50% of the labels gets corrupted, with log entries like above.
CALL FUNCTION 'RSPO_SR_WRITE_BINARY'
      EXPORTING
        handle           = lv_spool_handle
        data             = lv_label_line_bin
        length           = lv_len
        codepage         = '2010'
      EXCEPTIONS
        handle_not_valid = 1
        operation_failed = 2
        OTHERS           = 3.
Does anyone know if there is a way to send data to the spooler without character conversion or interpretation of printer control codes? Or is there any other smart way to get around this problem?
/Leif

Answer 1

I do a more direct output to the spooler, to avoid any issues with the WRITE statement and SAP's report output processing. At the same time, I insert line breaks so that the output is easy to debug in the spooler if needed. Also included is the code to to detect the escape code (ASCII #28) and to insert a control code ZZUPS in its place (you can skip this for Fedex). Here's a simplified example, but please note this is for a Unicode system, some minor changes is required in a non-Unicode system.
CONSTANTS: lc_spcode TYPE c LENGTH 5 VALUE 'ZZUPS',
           lc_xlen TYPE i VALUE 5.
   DATA: lv_print_params TYPE pri_params,
         lv_spool_handle TYPE sy-tabix,
         lv_name TYPE tsp01-rq0name,
         lv_spool_id TYPE rspoid,
         lv_crlf(2) TYPE c,
         lv_lf TYPE c,
         lstr_label_data TYPE zship_label_data_s,
         lv_label_line TYPE char512,
         lv_label_line_bin TYPE x LENGTH 1024,
         lv_len TYPE i,
         ltab_label_data_255 TYPE TABLE OF char512,
         ltab_label_data TYPE TABLE OF x,
         lv_c1 TYPE i,
         lv_c2 TYPE i,
         lv_cnt1 TYPE i,
         lv_cnt2 TYPE i,
         lv_x(2) TYPE x.
   FIELD-SYMBOLS: <n> TYPE x.
   lv_crlf = cl_abap_char_utilities=>cr_lf.
   lv_lf = lv_crlf+1(1).
   lv_name = 'ZPLLBL'.
CALL FUNCTION 'RSPO_SR_OPEN'
     EXPORTING
       dest                   = i_dest
       name                   = lv_name
       prio                   = '5'
       immediate_print        = 'X'
       titleline              = i_title
       receiver               = sy-uname
*      lifetime               = '0'
       doctype                = ''
     IMPORTING
       handle                 = lv_spool_handle
       spoolid                = lv_spool_id
     EXCEPTIONS
       device_missing         = 1
       name_twice             = 2
       no_such_device         = 3
       operation_failed       = 4
       OTHERS                 = 5.
   IF sy-subrc <> 0.
     RAISE spool_open_failed.
   ENDIF.
LOOP AT i_label_data INTO lstr_label_data.
     CLEAR ltab_label_data_255.
     SPLIT lstr_label_data-label_data AT lv_lf INTO TABLE ltab_label_data_255.
     LOOP AT ltab_label_data_255 INTO lv_label_line.
       IF lv_label_line NE ''.
         lv_len = STRLEN( lv_label_line ).
*       Convert character to hex type
         lv_c1 = 0.
         lv_c2 = 0.
         DO lv_len TIMES.
           ASSIGN lv_label_line+lv_c1(1) TO <n> CASTING.
           MOVE <n> TO lv_x.
           IF lv_x = 28.
             lv_cnt1 = 0.
             lv_label_line_bin+lv_c2(1) = lv_x.
             lv_c2 = lv_c2 + 1.
             DO lc_xlen TIMES.
               ASSIGN lc_spcode+lv_cnt1(1) TO <n> CASTING.
               MOVE <n> TO lv_x.
               lv_cnt2 = lv_c2 + lv_cnt1.
               lv_label_line_bin+lv_c2(2) = lv_x.
               lv_c2 = lv_c2 + 2.
               lv_cnt1 = lv_cnt1 + 1.
               lv_len = lv_len + 1.
             ENDDO.
           ELSE.
             lv_label_line_bin+lv_c2(2) = lv_x.
             lv_c2 = lv_c2 + 2.
           ENDIF.
           lv_c1 = lv_c1 + 1.
         ENDDO.
*       Print binary data to spool
         lv_len = lv_len * 2. "Unicode is 2 bytes per character
         CALL FUNCTION 'RSPO_SR_WRITE_BINARY'
           EXPORTING
             handle                 = lv_spool_handle
             data                   = lv_label_line_bin
             LENGTH                 = lv_len
           EXCEPTIONS
             handle_not_valid       = 1
             operation_failed       = 2
             OTHERS                 = 3.
         IF sy-subrc <> 0.
           RAISE spool_write_failed.
         ENDIF.
       ENDIF.
     ENDLOOP.
   ENDLOOP.
   CALL FUNCTION 'RSPO_SR_CLOSE'
     EXPORTING
       handle = lv_spool_handle.
   IF sy-subrc <> 0.
     RAISE spool_close_failed.
   ENDIF.