Problem in generating the output

Question

Hi,
I am new to Oracle XML.I'm using Oracle 10g(10.1 - 10.2) as my backend DB. I have the code below. Its purpose is to display the following values:
for id_number:
1
2
for first_name:
JOHN
MICHAEL
CREATE OR REPLACE procedure parse_CLOB1 as
l_clob CLOB := '';
l_parser dbms_xmlparser.Parser;
l_doc dbms_xmldom.DOMDocument;
l_nl dbms_xmldom.DOMNodeList;
l_cnl dbms_xmldom.DOMNodeList;
l_inl dbms_xmldom.DOMNodeList;
l_n dbms_xmldom.DOMNode;
l_childNode dbms_xmldom.DOMNode;
l_icnode dbms_xmldom.DOMNode;
l_default_path VARCHAR2(33) := '/EMPLOYEE_REC/EMPLOYEES/RECORD';
l_temp VARCHAR2(500) := '';
l_value VARCHAR2(500) := '';
begin
l_clob := '<EMPLOYEE_REC>
<DEPARTMENT>104</DEPARTMENT>
<EMPLOYEES>
<RECORD>
<ID_NUMBER>1</ID_NUMBER>
<FIRST_NAME>JOHN</FIRST_NAME>
</RECORD>
<RECORD>
<ID_NUMBER>2</ID_NUMBER>
<FIRST_NAME>MICHAEL</FIRST_NAME>
</RECORD>
</EMPLOYEES>
</EMPLOYEE_REC>';
l_parser := dbms_xmlparser.newParser;
dbms_xmlparser.parseClob(l_parser, l_clob);
l_doc := dbms_xmlparser.getDocument(l_parser);
l_nl := dbms_xslprocessor.selectNodes(dbms_xmldom.makeNode(l_doc),l_default_path);
FOR c IN 0 .. (dbms_xmldom.getLength(l_nl) - 1)
LOOP
l_n := dbms_xmldom.item(l_nl, c);
l_cnl := dbms_xmldom.getchildnodes(l_n);
l_childnode := dbms_xmldom.item(l_cnl, c);
l_temp := dbms_xmldom.getnodename(l_childnode);
dbms_output.put_line('The value of the inner element is: '||l_temp);
-- get the value of the inner node
     l_inl := dbms_xslprocessor.selectNodes(dbms_xmldom.makeNode(l_doc),l_default_path||'/'||l_temp);
     for d in 0 .. (dbms_xmldom.getLength(l_inl) - 1)
     loop
     l_icnode := dbms_xmldom.item(l_inl, c);
     l_value := dbms_xmldom.getnodevalue(dbms_xmldom.getfirstchild(l_icnode));
     dbms_output.put_line(l_value);
     end loop;
end loop;
dbms_xmldom.freeDocument(l_doc);
EXCEPTION
WHEN OTHERS THEN
dbms_output.put_line('FAIL');
dbms_output.put_line(sqlerrm);
dbms_lob.freetemporary(l_clob);
dbms_xmlparser.freeParser(l_parser);
dbms_xmldom.freeDocument(l_doc);
end parse_CLOB1;
My problem is that I'm getting the wrong output below:
The value of the inner element is: ID_NUMBER
1
1
The value of the inner element is: FIRST_NAME
MICHAEL
MICHAEL
Can you help me about this?
Thanks,
Jun

Answer 1

Hi,
I already found the cause. I still use the variable c in my inner loop which is supposed to be d
Regards,
Jun